filtre

[a10]

bonjour


j'ai une macro qui me filtre toutes les lignes avec :Criteria1:="<>"
Range("E2:aa50").Select
ActiveSheet.Range("$D$1:$BA$50").AutoFilter Field:=8, Criteria1:="<>"
Selection.Copy



mais si il ne trouve pas cela ne fonctionne pas

comment faire si le Criteria1:="<>" n 'est pas valide alors il indique un message pas de filtre

a++

 

[Dranreb]

Re : filtre

Bonsoir.

Sub test()
Range("E2:aa50").Select
On Error Resume Next
ActiveSheet.Range("$D$1:$BA$50").AutoFilter Field:=8, Criteria1:="<>"
If Err Then MsgBox "Pas de filtre.", vbCritical, "Zut !": Exit Sub
On Error GoTo 0
Selection.Copy
End Sub

 

[a10]

Re : filtre

bonjour,
j'ai essayé la macro
si le filtre colonne 8 est="<>" n'est pas valide
il met un message pas de filtre
met pour moi cette macro ne fonctionne pas.
est ce que cette macro fonctionne,

a+

 

[a10]

Re : filtre

bonjour,

voici le fichier

je voulais quand dans la colonne 18 il y a un g on copie si non message d'erreur

a+

 

[Dranreb]

Re : filtre

Essayez comme ça :

Sub test()
Dim Plage As Range
Set Plage = ActiveSheet.AutoFilter.Range
Plage.AutoFilter Field:=18, Criteria1:="<>"
Set Plage = Plage.Offset(1).Resize(Plage.Rows.Count - 1)
On Error Resume Next
Set Plage = Plage.SpecialCells(xlCellTypeVisible)
If Err Then Set Plage = Nothing
On Error GoTo 0
If Plage Is Nothing Then MsgBox "Pas de filtre.", vbCritical, "Zut !": Exit Sub
Plage.Copy
End Sub

 

[job75]

Re : filtre

Bonsoir a10, Bernard,

Sub test()
ActiveSheet.Range("D1:BA50").AutoFilter Field:=18, Criteria1:="g"
With ActiveSheet.AutoFilter.Range.SpecialCells(xlCellTypeVisible)
  If .Count = .Rows(1).Cells.Count Then MsgBox "Pas de filtre.", vbCritical, "Zut !": Exit Sub
  Intersect(.EntireRow, [E2:BA50]).Select 'mais en VBA il est inutile de sélectionner...
  Selection.Copy
End With
End Sub

A+

 

[a10]

Re : filtre

Bonjour,


If .Count = .Rows(1).Cells.Count Then MsgBox "Pas de filtre.", vbCritical, "Zut !": Exit Sub => Merci cela fonctionne, mais si je veux qu'apres cliqué sur pas de filtre ma macro continue apres le end with?
Intersect(.EntireRow, [E2:BA50]).Select
Selection.Copy
End With


A+🙂
End Sub

 

[job75]

Re : filtre

Bonjour le forum,

mais si je veux qu'apres cliqué sur pas de filtre ma macro continue apres le end with?

Pas encore bien réveillé ?

Sub test()
ActiveSheet.[D1:BA50].AutoFilter Field:=18, Criteria1:="g"
With ActiveSheet.AutoFilter.Range.SpecialCells(xlCellTypeVisible)
  If .Count = .Rows(1).Cells.Count Then
    MsgBox "Pas de filtre.", vbCritical, "Zut !"
    '1ère suite du code...
  Else
    Intersect(.EntireRow, [E2:BA50]).Copy
    '2ème suite du code...
  End If
End With
'3ème suite du code...
End Sub

Bonne journée.