Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

Microsoft 365 Filtre multi critères

E

eric72

XLDnaute Accro
‌Bonjour à tous,
Je rencontre un souci avec la fonction filtre sur un critere dont les données de comparaison se trouve sur plusieurs colonne:
VB: 
=SOMME(FILTRE(TbPropo[[Total Compta Récurrent]:[Total Social Exceptionnel]];
(SI($E$5<>"";TbPropo[Ville EC]=$E$5;1))*
(SI($B$9<>"";TbPropo[Statut]=$B$9;1))*
(SI($E$7<>"";TbPropo[Colonne1]=$E$7;1))*
(SI($E$9<>"";OU(TbPropo[Except Compta 1]=$E$9;TbPropo[Except Compta 2]=$E$9;TbPropo[Except Compta 3]=$E$9;1)))))


c'est ici que ça ne va pas:
Code: 
(SI($E$9<>"";OU(TbPropo[Except Compta 1]=$E$9;TbPropo[Except Compta 2]=$E$9;TbPropo[Except Compta 3]=$E$9;1)
J'imagine que le "ou" n'est pas approprié pour cette fonction mais je ne sais pas ou!!!
Merci beaucoup pour votre aide encore une fois
Eric
 

Pièces jointes

  • test filtre2.xlsm.xlsx
    28.4 KB · Affichages: 10
Solution
RE
J'obtiens 500 qui correspond au 2 lignes x 2 colonnes qui concernent Toto Jérome à Nantes
Détaille ce qui ne va pas...
Je n'ai fait que corriger ta syntaxe

Arf non j'ai affiché un résultat et oublié d'annuler et il faut ajouter un paramètre à Filtre
VB: 
=SOMME(FILTRE(TbPropo[[Total Compta Récurrent]:[Total Compta Exceptionnel]];
((SI($E$5<>"";TbPropo[Ville EC]=$E$5;1))*
(SI($B$9<>"";TbPropo[Statut]=$B$9;1))*
(SI($E$7<>"";TbPropo[Colonne1]=$E$7;1))*
(SI($E$9<>"";((TbPropo[Except Compta 1]=$E$9)+(TbPropo[Except Compta 2]=$E$9)+(TbPropo[Except Compta 3]=$E$9));1)));0))
Trier par date Trier par votes

chris

XLDnaute Barbatruc
Bonjour
VB: 
=SOMME(FILTRE(TbPropo[[Total Compta Récurrent]:[Total Compta Exceptionnel]];
((SI($E$5<>"";TbPropo[Ville EC]=$E$5;1))*
(SI($B$9<>"";TbPropo[Statut]=$B$9;1))*
(SI($E$7<>"";TbPropo[Colonne1]=$E$7;1))*
(SI($E$9<>"";((TbPropo[Except Compta 1]=$E$9)+(TbPropo[Except Compta 2]=$E$9)+(TbPropo[Except Compta 3]=$E$9));1)));0))
Edit corrigé
 
Dernière édition:
Vote positif 0 Vote négatif
E

eric72

XLDnaute Accro
Bonjour Chris,
Merci beaucoup pour ta réponse mais malheureusement ça ne fonctionne pas, le résultat n'est pas conforme, désolé.
Le résultat ne change pas lorsqu je sélectionne un critère
Merci
 
Vote positif 0 Vote négatif

chris

XLDnaute Barbatruc
RE
J'obtiens 500 qui correspond au 2 lignes x 2 colonnes qui concernent Toto Jérome à Nantes
Détaille ce qui ne va pas...
Je n'ai fait que corriger ta syntaxe

Arf non j'ai affiché un résultat et oublié d'annuler et il faut ajouter un paramètre à Filtre
VB: 
=SOMME(FILTRE(TbPropo[[Total Compta Récurrent]:[Total Compta Exceptionnel]];
((SI($E$5<>"";TbPropo[Ville EC]=$E$5;1))*
(SI($B$9<>"";TbPropo[Statut]=$B$9;1))*
(SI($E$7<>"";TbPropo[Colonne1]=$E$7;1))*
(SI($E$9<>"";((TbPropo[Except Compta 1]=$E$9)+(TbPropo[Except Compta 2]=$E$9)+(TbPropo[Except Compta 3]=$E$9));1)));0))
 
Dernière édition:
Vote positif 0 Vote négatif
Solution

TooFatBoy

XLDnaute Barbatruc
Bonjour,

Je ne sais pas ce que fait la fonction Filtre, mais peut-être qu'à l'ancienne, avec un SommeProd ???
Code: 
=SOMMEPROD((TbPropo[[Total Compta Récurrent]:[Total Social Exceptionnel]])*
(($B$9<>"")*(TbPropo[Statut]=$B$9))*
(($E$5<>"")*(TbPropo[Ville EC]=$E$5))*
(($E$7<>"")*(TbPropo[Colonne1]=$E$7))*
(($E$9<>"")*((TbPropo[Except Compta 1]=$E$9)+(TbPropo[Except Compta 2]=$E$9)+(TbPropo[Except Compta 3]=$E$9))))

Mais il doit manquer un filtre sur le mois et l'année je suppose, ce qui donnerait peut-être ceci :
Code: 
=SOMMEPROD((TbPropo[[Total Compta Récurrent]:[Total Social Exceptionnel]])*
(($B$9<>"")*(TbPropo[Statut]=$B$9))*
(($E$5<>"")*(TbPropo[Ville EC]=$E$5))*
(($E$7<>"")*(TbPropo[Colonne1]=$E$7))*
(($E$9<>"")*((TbPropo[Except Compta 1]=$E$9)+(TbPropo[Except Compta 2]=$E$9)+(TbPropo[Except Compta 3]=$E$9)))*
(MOIS(TbPropo[Date Propo])=MOIS($A13))*
(ANNEE(TbPropo[Date Propo])=ANNEE($B$3)))
 

Pièces jointes

  • test filtre2.xlsm.xlsx
    31.3 KB · Affichages: 2
Dernière édition:
Vote positif 0 Vote négatif
E

eric72

XLDnaute Accro
oui tu as raison, en fait ce que je voulais pour TOTO c'est le récurrent+l'exceptionnel qui correspond au critère "Except Compta1+exceptcompta2+exceptcompta3,
ce qui veut dire que j'ai mal construit ma formule, de plus j'aimerais aussi filtrer sur la période sélectionnée.
Merci beaucoup
 
Vote positif 0 Vote négatif
E

eric72

XLDnaute Accro
Bonsoir,
Merci pour ta réponse, je suis au boulot je regarde ça tout à l'heure à tête reposée...
 
Vote positif 0 Vote négatif
E

eric72

XLDnaute Accro
chris à dit:
RE

Avec 2 début et pas de fin cela n'aide pas à comprendre exactement ce que tu veux...
Cliquez pour agrandir...
bonjour Chris,
Désolé pou ce silence mais boulot oblige!! pour les 2 dates de début c'est juste avec les copier coller pour faire un fichier anonymisé je me suis un peu précipité.
L'important c'est qu'en utilisant vos réponses j'ai pu modifier mes formules et arriver à mes fins.
Merci beaucoup et bon dimanche.
 
Vote positif 0 Vote négatif
E

eric72

XLDnaute Accro
Bonjour TOOFATBOY,

Merci encore une fois pour ton aide, en fait j'ai ajouté une colonne que pour l'exceptionnel c'est plus simple.
Bon dimanche et merci encore
 
Vote positif 0 Vote négatif
E

eric72

XLDnaute Accro
chris à dit:
RE

Avec 2 début et pas de fin cela n'aide pas à comprendre exactement ce que tu veux...
Cliquez pour agrandir...
Bonjour Chris,
Je tente de filtrer sur ma période avec ce filtre:
VB: 
SOMME(FILTRE(TbPropo[[Total Compta Récurrent]:[Total Social Exceptionnel]];
(SI($E$5<>"";TbPropo[Ville EC]=$E$5;1))*
(SI($B$9<>"";TbPropo[Statut]=$B$9;1))*
(SI($E$7<>"";TbPropo[Colonne1]=$E$7;1))*
(SI(A13<>"";MOIS(TbPropo[Date Propo]=MOIS(A13))))))
mais cela ne fonctionne pas, il ne tient pas compte du mois, qu'ai je fait de mal?
Merci beaucoup
 

Pièces jointes

  • test filtre2.xlsm.xlsx
    29.6 KB · Affichages: 0
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.

Discussions similaires

S
  • Résolu(e)
Microsoft 365 [RESOLU] Excel : Calcul de prix en fonction d'un type
Réponses
4
Affichages
217
JHA
J
D
  • Question
XL 2021 Filtre Multi Critères Listview VBA
2
Réponses
21
Affichages
1 K
Dranreb
T
  • Question
Microsoft 365 Ajout d'une conditions dans une formule Somme.si.ens
Réponses
2
Affichages
467
OKBI
O
T
  • Résolu(e)
Microsoft 365 VBA code filtre auto en boucle - plusieurs critères
2
Réponses
28
Affichages
2 K
tnion
T
  • Question
XL 2010 Reporte de calcul suivant critères
Réponses
12
Affichages
989
jeanmi
J
  • Question
Microsoft 365 Excel 2022 Formulaire VBA - Filtre Multi-Critères en Simultané
Réponses
1
Affichages
2 K
cp4
M
  • Question
XL 2019 Recherchex multi-critères avec date +/- 3 jours
Réponses
14
Affichages
2 K
MariaDatascience
M
R
  • Résolu(e)
XL 2019 Filtre et/ou MFC
Réponses
4
Affichages
946
Roxoneil
R
  • Question
XL 2010 RechercheV multi-critères en fonction d'une autre donnée
Réponses
8
Affichages
1 K
samimi94
D
  • Question
XL pour MAC Retraitement (trop complexe pour moi) d'une base de données
3 4 5
Réponses
74
Affichages
10 K
didcac
D
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…