Faire de plusieurs colonnes une seule, en les mettant à la suite.

[Branzahm]

Bonjour,
Je voudrais savoir comment est il possible de mettre une centaine de colonnes bout à bout pour en créer au final qu'une seule.
Exemple:





Et le faire pour un grand nombre de colonnes avec dans mon cas toujours 6 linges par colonne.
Merci d'avance.

 

[Vilain]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Bonjour,

La solution se trouve du côté de la fonction décaler je pense, mais sans fichier, un peu dur de te répondre...

a plus

 

[Branzahm]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Un fonction décaler? Comment s'utilise elle?
Voici un fichier excel :

 

[Vilain]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Re,

Je viens de découvrir ça récemment et suis pas encore hyper à l'aise avec.
=DECALER(B30;-5;1; attention, il y a un smiley car les signes ; et ) sont collés
Cela convient pour le début, il faut la compléter avec une si en lui disant que si c'est vide, elle passe à la colonne suivante.
Regarde ici : Ce lien n'existe plus
C'est le merveilleux site de Misange qui regorge d'astuces et de tutos utiles.

A plus

 

[Branzahm]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Merci bien pour la rapidité des réponses.
Je vais essayer de voir avec ça, merci
Cependant comment faire passer la formule sur une autre colonne si on arrive sur une cellule vide?
Car j'arrivais également à obtenir un peu cela avec la fonction Index.

à plus.

 

[Vilain]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Re,

Je pense que tu as intérêt à numéroter tes colonnes (la première étant à 0).
Il risque d'y avoir 2 fonctions décaler imbriquées, mais je n'y arrive pas pour le moment et n'ai pas beaucoup de temps.
N'y a-t-il pas un formuliste chevronné par ici ? Misange ? Hoerwind ? Rachid ? Quelqu'un d'autre ?

 

[Vilain]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Une autre solution consisterait à écrire cette formule sous vba avec une boucle pour le décalage de colonne, mais là, je ne peux pas, car n'étant pas très bon sous vba, ça me prendrait certainement assez longtemps.

A plus

 

[R@chid]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Bonjour @ tous,
une solution avec INDEX/EQUIV,
Formule en A12 @ tirer vers le bas :

=SI(LIGNES($12:12)<=COLONNES(Base)*LIGNES(Base);INDEX(Base;MOD(LIGNES($12:12)-1;LIGNES(Base))+1;MOD(ENT((MOD(LIGNES($1:1)-1;COLONNES(Base)*LIGNES(Base)))/LIGNES(Base));COLONNES(Base))+1);"")

Voir PJ.
Amicalement

 

[Vilain]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Re, Salut Rachid

Peux tu détailler un peu cette formule stp, je la comprend pas très bien.

A plus

 

[R@chid]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Bonjour Gillus69,
ca te plait ???
en B12 :

=MOD(LIGNES($12:12)-1;LIGNES(Base))+1

en C12 :

=MOD(ENT((MOD(LIGNES($1:1)-1;COLONNES(Base)*LIGNES(Base)))/LIGNES(Base));COLONNES(Base))+1

tires les formules en Bas et remarques ce qui se passe.
Amicalement

 

[BOISGONTIER]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Bonsoir,

Transforme tableau

http://boisgontierjacques.free.fr/fichiers/decaler/Decaler3col1col.xls

JB

 

[Vilain]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Oui, ça me plait pas mal,

Je ne sais pas utiliser ni mod ni ent comme tu le fais, je n'ai d'ailleurs jamais trouvé grande utilité à ces fonctions...

Merci

 

[Vilain]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Salut Boisgontier,

Comme bien souvent, tu apparaît, comme sorti de nul part, avec un message sobre et des explications complètes. Merci beaucoup !

A plus

 

[R@chid]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Bonjour @ tous,
Avec DECALER, en A12 :

=SI(LIGNES($12:12)<=COLONNES(Base)*LIGNES(Base);DECALER(A$4;MOD(LIGNES($12:12)-1;LIGNES(Base))+1;MOD(ENT((MOD(LIGNES($1:1)-1;COLONNES(Base)*LIGNES(Base)))/LIGNES(Base));COLONNES(Base)));"")

Amicalement

 

[R@chid]

Re : Faire de plusieurs colonnes une seule, en les mettant à la suite.

Bonsoir @ tous,
Apres avoir lu la reponse du prof Boisgontier, je me permets de simplifier ma premiere reponse avec INDEX/EQUIV, en A12 :

=SI(LIGNES($12:12)<=COLONNES(Base)*LIGNES(Base);INDEX(Base;MOD(LIGNES($12:12)-1;LIGNES(Base))+1;ENT((LIGNES($12:12)-1)/LIGNES(Base))+1);"")

.
@ tirer vers le bas.
Amicalement