Microsoft 365 Excel très basique mais je bug !

[Alexis123456]

Bonjour,

Ma question concerne une base d’Excel.

Les deux fonctions ci-dessous (deux façons de faire la même chose) sont redondantes : elles répètent l’argument de recherche.
J’aimerais trouver une alternative qui raccourcirait la fonction pour la rendre plus facilement lisible et éviter cette imbrication (car je vais devoir imbriquer plein d’autres choses par la suite).
Je n’ai seulement connaissance de la fonction SIERREUR qui place la condition par défaut comme résultat, mais je ne trouve rien avec les fonctions SI.

=SI(RECHERCHEV(A5;N3:S6;2;FAUX)="";"";RECHERCHEV(A5;N3:S6;2;FAUX))
=SI(ESTVIDE(RECHERCHEV(A5;N3:S6;2;FAUX));"";RECHERCHEV(A5;N3:S6;2;FAUX))

Merci

 

[sylvanu]

Bonjour Alexis,
Peut être une piste avec simplement :

=RECHERCHEV(A5;N3:S6;2;FAUX)

et décocher l'option "afficher zéro"

 

[Alexis123456]

Salut,
Dans mon cas je veux garder les zéros affichés car ils seront une information à voir dans d’autres cellules du fichier.
De plus, l’option ne semble pas exister depuis Excel Microsoft 365 (la version en ligne).

 

[sylvanu]

Alors essayez peut être :

=RECHERCHEV(A5;N3:S6;2;FAUX)&""

Sur XL2007 ça marche.

 

[job75]

Bonjour Alexis123456, sylvanu,

En tenant compte du fait que RECHERCHEV peut renvoyer une valeur d'erreur :

=SI(ESTERREUR(RECHERCHEV(A5;N3:S6;2;FAUX))+ESTVIDE(RECHERCHEV(A5;N3:S6;2;FAUX));"";RECHERCHEV(A5;N3:S6;2;FAUX))

A+

 

[Alexis123456]

Alors essayez peut être :

=RECHERCHEV(A5;N3:S6;2;FAUX)&""

Sur XL2007 ça marche.

Super, je ne connaissais pas, merci !

En revanche, on n'a pas d'option pour éviter de répéter des fonctions dans SI ? (dans une approche plus globale d'excel)

 

[job75]

L'inconvénient de la solution de sylvanu c'est qu'elle transforme les nombres en textes.

Mais si elle vous convient vous pouvez la compléter par :

=SIERREUR(RECHERCHEV(A5;N3:S6;2;FAUX)&"";"")

Il y a aussi la formule que j'ai donnée au post #5.

 

[job75]

Vous êtes sur Microsoft 365, vous pouvez donc utiliser la fonction LET :

=LET(X;RECHERCHEV(A5;N3:S6;2;FAUX);SI(ESTERREUR(X)+ESTVIDE(X);"";X))