ERREUR EXECUTION '13' : icompatibilité de type. ou ERR '28' : espace pile insufisant

[MICHAEL]

Bonjour,

Pour quelle raison lorsque je supprime les données colonne B6 à B145 ainsi que k6 à k145
J'obtiens ces messages d'erreurs?


Merci pour vos réponses.

 

[mutzik]

Re : ERREUR EXECUTION '13' : icompatibilité de type. ou ERR '28' : espace pile insufi

bonjour,

essaie en début de ta macro (dans chaque feuille)
if target.cells.count > 1 then exit sub

 

[Pierrot93]

Re : ERREUR EXECUTION '13' : icompatibilité de type. ou ERR '28' : espace pile insufi

Bonjour,

essaye peut être comme suit :

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
If Not Intersect(Target, Range("B4:B145")) Is Nothing Then
Target = DateSerial(Cells(1, Target.Column), Month(Target), Day(Target))
End If
End Sub

bon après midi
@+

 

[Pierrot93]

Re : ERREUR EXECUTION '13' : icompatibilité de type. ou ERR '28' : espace pile insufi

Re,

A noter, si ce code doit s'appliquer à toutes les feuilles de ton classeur tu peux le placer une seule fois comme ceci, dans le module "thisworkbook" :

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
If Not Intersect(Target, Range("B4:B145")) Is Nothing Then
Target = DateSerial(Cells(1, Target.Column), Month(Target), Day(Target))
End If
End Sub

 

[ERIC S]

Re : ERREUR EXECUTION '13' : icompatibilité de type. ou ERR '28' : espace pile insufi

Bonjour

exemple sur 2018
si tu effaces une des dates en B, ta macro considère que tu es dans la zone où elle agit, sauf que ton contenu est vide, donc pas une date
il faudrait tester si date :

Private Sub Worksheet_Change(ByVal Target As Range)

If Not Intersect(Target, Range("B4:B145")) Is Nothing Then
If IsDate(Target.Value) Then Target = DateSerial(Cells(1, Target.Column), Month(Target), Day(Target))
End If
End Sub

 

[Dranreb]

Re : ERREUR EXECUTION '13' : icompatibilité de type. ou ERR '28' : espace pile insufi

Bonjour.

Tout cela ne répond pas à la question du demandeur.
Ce sont sans nul doute deux conséquences de la Private Sub Worksheet_Change dans les feuilles.
Il n'y est pas vérifié qu'une seule cellule est modifiée de sorte que la valeur de plusieurs est constituée d'un tableau qui ne saurait constituer un argument valable des fonctions Month et Day. Par ailleurs en l'absence d'instruction Application.EnableEvents = False devant la modification de Target, celle ci provoque aussitôt une ré-exécution de la Worksheet_Change alors que celle ci n'est pas encore terminée, d’où saturation de la pile quand des millions d'exécutions non terminées sont engagées.

 

[MICHAEL]

Re : ERREUR EXECUTION '13' : icompatibilité de type. ou ERR '28' : espace pile insufi

Dans ce cas est il possible d'écrire un vb cohérent et fonctionnel en reprenant le vb existant, et comment faire?

cordialement

 

[Dranreb]

Re : ERREUR EXECUTION '13' : icompatibilité de type. ou ERR '28' : espace pile insufi

D'autre l'on déjà fait, sauf pour ce qui est du Application.EnableEvents = False.
Je dirais donc :

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Or Intersect(Target, Range("B4:B145")) Is Nothing Then Exit Sub
If IsDate(Target.Value) Then
   Application.EnableEvents = False
   Target = DateSerial(Me.[B1].Value, Month(Target), Day(Target))
   Application.EnableEvents = True
   End If
End Sub

 

[MICHAEL]

Re : ERREUR EXECUTION '13' : icompatibilité de type. ou ERR '28' : espace pile insufi

Merci Dranreb! oui cela fonctionne tout a fait
Merci à tous et bonne soirée

cordialement