Microsoft 365 Erreur Calc avec Filtre

[eric72]

Bonjour à tous,
Je m'en remets une nouvelle fois à votre savoir pour régler un petit problème d'erreur Calc qui me renvoie un "1" quand il ne trouve pas de correspondance.
Voilà la formule employée:

NBVAL(UNIQUE(FILTRE(TbSaisieFormations[NOM - PRENOM];(TbSaisieFormations[SEXE]=L$1)*(TbSaisieFormations[CSP]="ALTERNANT")*(TbSaisieFormations[DATE DE FIN]>=$K3)*(TbSaisieFormations[DATE DE FIN]<=DATE(ANNEE($K3)+1;1;0)))))

J'ai bien essayé avec "SIERREUR", avec "SI(ESTERREUR" mais rien n'y fait.
Merci beaucoup pour un petit coup de main et votre dévouement.
Bonne journée.

 

[danielco]

Bonjour,
"normal" ! Quand il n'y a pas de correspondance, FILTRE renvoie "#CALC!" qui est une valeur d'erreur, mais une valeur quand même et donc qui compte pour 1. Essaie :

=LET(flt;FILTRE(TbSaisieFormations[NOM - PRENOM];(TbSaisieFormations[SEXE]=L$1)*(TbSaisieFormations[CSP]="ALTERNANT")*(TbSaisieFormations[DATE DE FIN]>=$K3)*(TbSaisieFormations[DATE DE FIN]<=DATE(ANNEE($K3)+1;1;0));"");SI(flt="";0;NBVAL(UNIQUE(flt))))

=LET(flt;FILTRE(TbSaisieFormations[NOM - PRENOM];(TbSaisieFormations[SEXE]=L$1)*(TbSaisieFormations[CSP]="ALTERNANT")*(TbSaisieFormations[DATE DE FIN]>=$K2)*(TbSaisieFormations[DATE DE FIN]<=DATE(ANNEE($K2)+1;1;0));"");SI(PRENDRE(flt;1)="";0;NBVAL(UNIQUE(flt))))

Daniel

 

[eric72]

Bonjour,
"normal" ! Quand il n'y a pas de correspondance, FILTRE renvoie "#CALC!" qui est une valeur d'erreur, mais une valeur quand même et donc qui compte pour 1. Essaie :

=LET(flt;FILTRE(TbSaisieFormations[NOM - PRENOM];(TbSaisieFormations[SEXE]=L$1)*(TbSaisieFormations[CSP]="ALTERNANT")*(TbSaisieFormations[DATE DE FIN]>=$K3)*(TbSaisieFormations[DATE DE FIN]<=DATE(ANNEE($K3)+1;1;0));"");SI(flt="";0;NBVAL(UNIQUE(flt))))

=LET(flt;FILTRE(TbSaisieFormations[NOM - PRENOM];(TbSaisieFormations[SEXE]=L$1)*(TbSaisieFormations[CSP]="ALTERNANT")*(TbSaisieFormations[DATE DE FIN]>=$K2)*(TbSaisieFormations[DATE DE FIN]<=DATE(ANNEE($K2)+1;1;0));"");SI(PRENDRE(flt;1)="";0;NBVAL(UNIQUE(flt))))

Daniel

Bonjour Danielco,
Merci pour la réponse, cela parait efficace par contre je suis incapable de le reproduire, est-il possible d'avoir des explications?
Merci beaucoup

 

[danielco]

Bonjour Danielco,
Merci pour la réponse, cela parait efficace par contre je suis incapable de le reproduire, est-il possible d'avoir des explications?
Merci beaucoup

Pour le filtre, j'ai ajouté à la fin le paramètre "" qui renvoie une chaîne vide i FILTRE ne trouve pas de correspondance. J'ai appelé le filtre "flt" au moyen de LET pour éviter de le recalculer deux fois. Ensuite, j'ai testé si la première valeur du filtre est "" (quand il n'y a pas de correspondance). Dans ce cas, la formule renvoie "0" sinon, elle renvoie le nombre trouvé :

Daniel

 

[eric72]

Pour le filtre, j'ai ajouté à la fin le paramètre "" qui renvoie une chaîne vide i FILTRE ne trouve pas de correspondance. J'ai appelé le filtre "flt" au moyen de LET pour éviter de le recalculer deux fois. Ensuite, j'ai testé si la première valeur du filtre est "" (quand il n'y a pas de correspondance). Dans ce cas, la formule renvoie "0" sinon, elle renvoie le nombre trouvé :

Regarde la pièce jointe 1227006

Regarde la pièce jointe 1227005
Daniel

Ah Ok je comprends mieux comme cela.
Merci beaucoup encore une fois et bonne journée.