Empecher l'affichage de la croix sur un userform

[pias]

Rebonsoir, le forum

Pour éviter que les utilisateurs ne ferment un userform, je voudrais enlever la croix en haut à droite.

Je mets le code ci-dessus, mais il y a erreur.
Merci d'avance si quelqu'un trouve la solution.

a+
@pias

Private Declare Function GetWindowLongA Lib "User32" _
(ByVal hWnd As Long, ByVal nIndex As Long) As Long

Private Declare Function SetWindowLongA Lib "User32" _
(ByVal hWnd As Long, ByVal nIndex As Long, _
ByVal dwNewLong As Long) As Long

Private Declare Function FindWindowA Lib "User32" _
(ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Sub UserForm_Initialize()
Dim hWnd As Long
hWnd = FindWindowA("Thunder" & IIf(Application.Version Like "8*", _
"X", "D") & "Frame", Me.Caption)
SetWindowLongA hWnd, -16, GetWindowLongA(hWnd, -16) And &HFFF7FFFF
End Sub

Private Sub UserForm_Activate()

UserForm1.Caption = Worksheets("config").Range("B3")


With TextBox1
.SetFocus ' Ce code pour sélectionner
.SelStart = 0
.SelLength = Len(TextBox1.Text)
End With
End Sub

 

[michel]

bonjour Pias

une autre solution consiste à empecher l'action de la croix sans la faire disparaître
la solution n'est pas de moi . Que l'auteur m'excuse et se fasse connaître , car à l'epoque j'avais oublié de noter son nom…

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode = vbFormControlMenu Then
MsgBox "Vous ne pouvez pas utiliser ce bouton de fermeture." & Chr(10) _
& "Pour fermer cette boîte de dialogue, veuillez utiliser le bouton Annuler"
Cancel = True
End If
End Sub

bon dimanche
michel


ps
si tu supprimes l'action de la croix , il ne faut pas oublier de crééer un autre bouton pour fermer l'userform , sinon tu vas bloquer l'application

 

[pias]

Bonjour,
La solution me convient car le but voulu est d’obliger a cliquer sur un autre bouton pour quitter l’userform.

Merci beaucoup, michel et bon dimanche a toi aussi.

Amicalement
@pias