Démmarer et arreter le clignetement d'une cellule automatiquement sous conditions

chaelie2015 · 30 Décembre 2015

Bonjour forum
Dans la feuille1 j’ai une cellule N13(fusionné N-Q) et cellule S13(fusionnée S-V)
je souhaite faire clignoter la cellule S13 automatiquement si
N13 inférieure ou égale a la date AUJOURDHUI() et une fois la cellule S13 est renseignée arrêté le clignotement
SALUTATIONS

Dranreb · 30 Décembre 2015

Re : Démmarer et arreter le clignetement d'une cellule automatiquement sous condition

Bonjour.

Dans Feuil1 :

VB:

Option Explicit

Private Sub Worksheet_Activate()
Test
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
Test
End Sub

Private Sub Test()
If Me.[N13].Value <= Date Then LancerClign Else StopperClign
End Sub

Dans un module standard :

VB:

Option Explicit
Private Temps As Date, Top As Boolean
Sub LancerClign()
If Temps = 0 Then Clignottement
End Sub
Sub StopperClign()
If Temps = 0 Then Exit Sub
With Feuil1.[S13]: .Interior.Color = &HFFA5&: .Font.Color = 0: End With
Application.OnTime Temps, "Clignottement", Schedule:=False
Temps = 0
End Sub
Sub Clignottement()
With Feuil1.[S13]: .Interior.Color = IIf(Top, &HFFFF&, &HFF&)
   .Font.Color = IIf(Top, &HFF&, &HFFFF&): End With
Top = Not Top
Temps = Now + TimeSerial(0, 0, 1)
Application.OnTime Temps, "Clignottement"
End Sub

chaelie2015 · 31 Décembre 2015

Re : Démmarer et arreter le clignetement d'une cellule automatiquement sous condition

Bonjour BERNARD
MERCI, c'est parfait,
Pblm résolu
SALUTATIONS

Démmarer et arreter le clignetement d'une cellule automatiquement sous conditions

chaelie2015

XLDnaute Accro

Pièces jointes

Dranreb

XLDnaute Barbatruc

chaelie2015

XLDnaute Accro

Discussions similaires