définir une plage sans activate

[jhofman]

Bonjour,

je cherche à définir une plage. dans mon classeur pour un onglet appelé ONglet.
avec la première méthode ça marche bien mais je souhaite ne pas utiliser la fonction Activate

ThisWorkbook.Sheets(ONglet).Activate
L = ThisWorkbook.Sheets(ONglet).Cells(65536, Colonne).End(xlUp).Row 'dernière ligne du tableau
Set MaPlage = ActiveWorkbook.Sheets(ONglet).Range(Cells(2, Colonne), Cells(L, Colonne))

avec cette méthode ça marche aussi mais le nom de la colonne est figée.

L = ThisWorkbook.Sheets(ONglet).Cells(65536, Colonne).End(xlUp).Row 'dernière ligne du tableau
 Set MaPlage = ThisWorkbook.Worksheets(ONglet).Range("B2:B" & L)

je souhaite utiliser ce code mais cela ne fonctionne pas :
- ni activation de l'onglet
- ni écriture en dur de la colonne.
.... mais cela ne fonctionne pas.
🙂

L = ThisWorkbook.Sheets(ONglet).Cells(65536, Colonne).End(xlUp).Row 'dernière ligne du tableau
Set MaPlage = ThisWorkbook.Worksheets(ONglet).Range(Cells(2, Colonne), Cells(L, Colonne))

 

[tototiti2008]

Re : définir une plage sans activate

Bonjour jhofman,

essaye :

L = ThisWorkbook.Sheets(ONglet).Cells(65536, Colonne).End(xlUp).Row 'dernière ligne du tableau
With ThisWorkbook.Worksheets(ONglet)
Set MaPlage = .Range(.Cells(2, Colonne), .Cells(L, Colonne))
End with

les Cells dans le Range doivent pointer sur la même feuille, par défaut ils font référence à la feuille active

 

[jhofman]

Re : définir une plage sans activate

merci encore tototiti2008

ça marche bien. ... mais j'ai du mal à comprendre pourquoi.
Cordialement
José

 

[tototiti2008]

Re : définir une plage sans activate

une petite explication complémentaire :

si tu mets la ligne

Range("A1").select

VBA part du principe que tu veux sélectionner la cellule A1 de la feuille Active

si tu mets

Worksheets("Feuil1").range(cells(1,1), cells(5,1)).value
le Range pointe sur la feuil1 mais les Cells pointent sur la feuille active, ce qui peut poser des problèmes
avec
With Worksheets("Feuil1")
.range(.cells(1,1), .cells(5,1)).value
end with
tout pointe sur la Feuil1

 

[jhofman]

Re : définir une plage sans activate

plus clair et pas intuitif...

Merci bien.
josé🙂