"déconcaténer"

zesuila · 2 Novembre 2009

bonjour à tous
voilà je dois "déconcatener" cette ligne (en fait j'en ai 300 !!)
pierre voilou * Place Roger Salengro 69190 Ville Saint-Fons ( 04 78 78 78 78 ) Ê 04 78 79 79 79- pierre.voilou@wanadoo.fr Type bmw puissance 1200
Ce qui ressemblerai à la fin à :
pierre voulou en a2
place roger salengro en b2
code postal en c2
ville en d2
tel en e2
fax (c'est le Ê !) en f2
email en g2
type en h2

j'ai tenté les gauche, les droites, les equiv "piqués " sur le forum mais je n'y arrive pas !
et vous ?
Merci

Tibo · 2 Novembre 2009

Re : "déconcaténer"

Bonjour,

Une tentative, avec quelques matricielles :

Ton texte en A2.

en B2 :

Code:

=GAUCHE(A2;TROUVE("*";A2)-1)

en C2, une matricielle :

Code:

=STXT(A2;TROUVE("*";A2)+2;EQUIV(1;ESTNUM((STXT(A2;LIGNE(INDIRECT("1:"&
NBCAR(A2)));6)*1))*1;0)-TROUVE("*";A2)-2)

à valider par CTRL + MAJ + ENTREE

EN D2, une autre matricielle :

Code:

=STXT(A2;EQUIV(1;ESTNUM((STXT(A2;LIGNE(INDIRECT("1:"&
NBCAR(A2)));6)*1))*1;0);6)*1

à valider par CTRL + MAJ + ENTREE

en E2, encore une matricielle :

Code:

=STXT(A2;EQUIV(1;ESTNUM((STXT(A2;LIGNE(INDIRECT("1:"&
NBCAR(A2)));6)*1))*1;0)+7;TROUVE("(";A2)-EQUIV(1;ESTNUM((
STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));6)*1))*1;0)-8)

en F2 :

Code:

=STXT(A2;TROUVE("(";A2)+2;14)

en G2 :

Code:

=STXT(A2;TROUVE("Ê";A2)+2;14)

en H2 :

Code:

=STXT(STXT(A2;TROUVE("Ê";A2)+18;99);1;TROUVE("@";STXT(A2;TROUVE("Ê";A2)+18;99))+
TROUVE(".";STXT(STXT(A2;TROUVE("Ê";A2)+18;99);TROUVE("@";
STXT(A2;TROUVE("Ê";A2)+18;99));99))+1)

en I2 :

Code:

=STXT(A2;TROUVE("@";A2)+TROUVE(" ";STXT(A2;TROUVE("@";A2);99));99)

Ces formules supposent que les séparateurs soient toujours les mêmes et que la structure de tes chaïnes soient également toujours identiques.

Je te laisse tester

@+

zesuila · 2 Novembre 2009

Re : "déconcaténer"

super ! tout à l'air de fonctionner(bon il ya quelques "bugs" étant donné que comme tu le dis dans ta solution , tout doit être identique, et ce n'est pas le cas sur quelques lignes) mais c'est exactement ce que je cherchais ! A moi maintenant de potasser ce code.
encore merci Tibo

"déconcaténer"

zesuila

XLDnaute Occasionnel

Tibo

XLDnaute Barbatruc

zesuila

XLDnaute Occasionnel

"déconcaténer"

zesuila

XLDnaute Occasionnel

Tibo

XLDnaute Barbatruc

zesuila

XLDnaute Occasionnel

Privacy & Transparency

Privacy & Transparency