Couleur des cellules

JR PROD · 29 Juillet 2002

Bonjour tout le monde,

j'ai comme un petit problème avec Excel. J'aimerai en effet programmer une macro qui mettrait les cellules en différentes couleurs selon le chiffre marqué dedans.

Par exemple si j'ai 1 dans une cellule, qu'elle soit en vert après l'exécution de la macro.

Mon idée serait que
1 = vert p.ex
2 = jaune
3 = rouge

Ensuite je voudrais aller plus loin en faisant 1 - 10 = vert ; 11 - 20 = jaune ; 21-30 = rouge.

Pour l'instant j'en suis là, mais je n'arrive pas à faire fonctionner le tout. Quelqu'un pourrait-il m'aider ?

>>
Sub Couleurs()

Dim num As Integer

num = ActiveCell.Value

ActiveCell.Select

With Selection.Interior
#If Value = 1 Then
ActiveCell.Value = 5

#ElseIf Value = 2 Then
ActiveCell.Value = 6

#ElseIf Value = 3 Then
ActiveCell.Value = 7

#Else
ActiveCell.Value = 0

With Selection.Interior
.ColorIndex = num
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
End With

#End If
End With

End Sub
<<

D'avance merci bcp !

JR PROD - [excel pour un gros nul]

Ti · 29 Juillet 2002

Place ce code dans un module et ensuite appelle Change_Couleurs en lui spécifiant la plage de cellules sur laquelle il doit agir. Pour ajouter des conditions, il te suffit d'ajouter des Case...

****************************

Option Explicit

Const Noir = 1
Const Blanc = 2
Const Rouge = 3
Const Vert = 4
Const Bleu = 5
Const Jaune = 6
Const Violet = 7

Sub Change_Couleurs(Plage As Range)
Dim Cel As Range
For Each Cel In Plage
With Cel
Select Case .Value
'test en cas de cellule vide :
'Case ""
' .Interior.ColorIndex = Violet

Case 1 To 10
.Interior.ColorIndex = Vert
Case 11 To 20
.Interior.ColorIndex = Jaune
Case 21 To 30
.Interior.ColorIndex = Rouge
'etc.
'Case 31 To 40
' .Interior.ColorIndex = Bleu
End Select
End With
Next Cel
End Sub

Sub Test_Couleur()
Change_Couleurs Range("A1:C10")
End Sub

JR PROD · 29 Juillet 2002

Merci beaucoup,

c'est très gentil de m'avoir aidé,

à bientôt

JR PROD

andré · 1 Août 2002

je ne suis pas informaticien, donc je me bébrouille avec les moyens du bord !
Vois les formules conditionnelles de l'exemple ci-joint.

catherine · 1 Août 2002

Une solution "bestiale", sans écrire de macro, je te donne : menu Format mise en forme conditionnelle la valeur de la cellule est égale à 1 (ou est comprise entre 1 et 10)
cliquer sur le bouton Format et mettre le motif en vert, puis bouton Ajouter
et recommencer avec les valeurs 2 et 3.
Seul inconvénient (de taille!) tu ne peux indiquer que 3 possibiltés.

andré · 1 Août 2002

Petite copieuse !
C'est bon pour ... une fois (je suis belge).

phil · 26 Février 2003

Salut

je viens d'arriver sur le forum qui a l'air très interessant,
et je voulais savoir si pour des mots il y a aussi simple que pour l'exemple précedent

merci

andré · 26 Février 2003

Salut phil,

Ta question n'est pas suffisament précise pour qu'on puisse te donner une réponse immédiate.
Quel est le critère pour mettre les mots en couleur : la première lettre, la longueur du mot, ... ou autre chose ?
Si tu étais maraîcher, tu pourrais mettre une couleur à tous les fruits, une autre à tous les légumes, et une troisième à tous les condiments.
Tu pourrais même avoir un choix par une liste de validation.
N'oublie pas que sous la mise en forme conditionnelle, tu n'as que 3 possibilités (avec le fond blanc, cela en fait 4).

André.

Couleur des cellules

JR PROD

Guest

Ti

Guest

JR PROD

Guest

andré

Guest

Pièces jointes

catherine

Guest

andré

Guest

phil

Guest

andré

Guest

Discussions similaires