Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

Microsoft 365 Copier en VBA sans la mise en forme

F

Francky79

XLDnaute Occasionnel
Bonjour le forum,

Comment modifier ce code pour copier sans la mise en forme ?

VB: 
Sub lignes_livrées_Acno()
Dim dlg As Integer, lg As Integer, i As Integer
With ActiveSheet
    dlg = .Range("A" & Rows.Count).End(xlUp).Row
    For i = dlg To 2 Step -1
        If UCase(Range("I" & i)) = "2" Then
            lg = Sheets("Lignes_livrées_Acno").Range("A" & Rows.Count).End(xlUp).Row + 1
            .Range("A" & i & ":M" & i).Copy Sheets("Lignes_livrées_Acno").Range("A" & lg)
            .Rows(i).Delete
        End If
    Next
End With
End Sub

Il faudrait intégrer ce bout de code mais je ne sais pas comment faire.

Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False

Merci pour votre aide,
 
Solution
si tu veux juste les valeur ,pas besoins d'utiliser copy
simplement value=value
et meme pas besoins que le sheet de destination soit actif
cependant vaudrait mieux quand même préciser la feuille source concerné à la place de activesheet
remplace donc "tartampion" par le nom du sheets source
VB: 
Sub lignes_livrées_Acno()
    Dim dlg As Integer, i As Integer, plage As Range, destination As Range
    With sheets("tartampion")
        dlg = .Range("A" & Rows.Count).End(xlUp).Row
        For i = dlg To 2 Step -1
            If UCase(Range("I" & i)) = "2" Then  'pourquoi UCASE ici!!!???? pas besoins en fait !!!les chiffres et nombres n'ont pas de casse
                Set plage = .Range("A" & i & ":M" & i)
                Set...
Trier par date Trier par votes

patricktoulon

XLDnaute Barbatruc
si tu veux juste les valeur ,pas besoins d'utiliser copy
simplement value=value
et meme pas besoins que le sheet de destination soit actif
cependant vaudrait mieux quand même préciser la feuille source concerné à la place de activesheet
remplace donc "tartampion" par le nom du sheets source
VB: 
Sub lignes_livrées_Acno()
    Dim dlg As Integer, i As Integer, plage As Range, destination As Range
    With sheets("tartampion")
        dlg = .Range("A" & Rows.Count).End(xlUp).Row
        For i = dlg To 2 Step -1
            If UCase(Range("I" & i)) = "2" Then  'pourquoi UCASE ici!!!???? pas besoins en fait !!!les chiffres et nombres n'ont pas de casse
                Set plage = .Range("A" & i & ":M" & i)
                Set destination = Sheets("Lignes_livrées_Acno").Range("A" & Rows.Count).End(xlUp).Offset(1).Resize(1, plage.Columns.Count)
                destination.Value = plage.Value
                .Rows(i).Delete
            End If
        Next
    End With
End Sub
 
Vote positif 0 Vote négatif
Solution

vgendron

XLDnaute Barbatruc
Bonjour

et pourquoi pas juste
VB: 
Sub lignes_livrées_Acno()
Dim dlg As Integer, lg As Integer, i As Integer
With ActiveSheet
    dlg = .Range("A" & Rows.Count).End(xlUp).Row
    For i = dlg To 2 Step -1
        If UCase(Range("I" & i)) = "2" Then
            lg = Sheets("Lignes_livrées_Acno").Range("A" & Rows.Count).End(xlUp).Row + 1
            .Range("A" & i & ":M" & i).Copy 
            Sheets("Lignes_livrées_Acno").Range("A" & lg).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
            .Rows(i).Delete
        End If
    Next
End With
End Sub

cela dit.. sans fichier pas moyen de vérifier
il me semble que le pastespecial necessite de selectionner la cellule cible....
un rangeSource.copy rangedest.pastespecial n'est pas accepté par vba.. jamais compris pourquoi...
 
Vote positif 0 Vote négatif

Phil69970

XLDnaute Barbatruc
Bonjour @Francky79
Edit : Bonjour @patricktoulon , @vgendron

Je te propose :
VB: 
Sub lignes_livrées_Acno()
Dim dlg As Integer, lg As Integer, i As Integer
With ActiveSheet
    dlg = .Range("A" & Rows.Count).End(xlUp).Row
    For i = dlg To 2 Step -1
        If UCase(Range("I" & i)) = "2" Then
            lg = .Range("A" & Rows.Count).End(xlUp).Row + 1
            .Range("A" & lg & ":M" & lg) = .Range("A" & i & ":M" & i).Value
            .Rows(i).Delete
        End If
    Next
End With
End Sub

*Merci de ton retour

@Phil69970
 
Dernière édition:
Vote positif 0 Vote négatif

Jacky67

XLDnaute Barbatruc
Bonjour à tous

Le tout des codes donnés sans oublier le point devant "Range" et "Rows"
dlg = .Range("A" & .Rows.Count).End(xlUp).Row
'
If UCase(.Range("I" & i)) = "2" Then
ou
If .Range("I" & i) = 2 Then

selon.que 2 soit numérique ou pas
 
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.

Discussions similaires

M
  • Question
XL 2021 VBA Excel Erreur 2023
Réponses
2
Affichages
184
MICHIS
M
C
  • Résolu(e)
XL 2021 Additionner résultats d'une boucle for en vba
Réponses
9
Affichages
440
Claudinedu13
C
  • Question
Autres fenêtre "Publication"
Réponses
10
Affichages
426
ph.vanne
O
  • Question
Autres Optimisation macro numérotation ligne
Réponses
11
Affichages
213
crocrocro
C
P
  • Résolu(e)
XL 2013 EXCEL VBA
Réponses
2
Affichages
329
pangasoul
P
  • Question
Microsoft 365 L'indice n'appartient pas à la sélection
Réponses
8
Affichages
623
TooFatBoy
H
  • Résolu(e)
XL 2016 Copier cellule dans un autre onglets
2
Réponses
16
Affichages
323
Phil69970
M
  • Résolu(e)
XL 2021 PUBLIPOSTAGE : Mise en forme du corps de message issu d'une cellule excel (VBA)
Réponses
4
Affichages
371
Minus&Cortex
M
E
  • Résolu(e)
XL 2019 transfer listbox vers une colonne à partir de la 4 ligne
Réponses
2
Affichages
135
escudo
E
P
  • Question
XL 2019 Changer nom d'export en VBA
Réponses
3
Affichages
483
job75
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…