copie d'une feuille model + chgt d'une donnée.

[begastor]

Bonjour,

j'ai besoin d'un coup de main.

Dans un classeur, j'ai une feuille nommée "Activités".
En colonne A se trouve la liste des activités.
Je souhaite en double cliquant sur une activité, Ajouter au classeur une feuille type (elle s'appelle "model" dans mon classeur) qui porte de nom de l'activité, et dont la case A1 a pour valeur le nom de l'activité sur laquelle j'ai cliqué (ou le nom de la fiche créée puisque c'est le même...)

Suis-je clair ?

j'utilise cette fonction:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim cel As Range
Dim ws As Worksheet
Dim Nom As String

If Target.Column <> 1 Then Exit Sub
On Error Resume Next
Nom = Target.Value
If Nom = "" Then Exit Sub
For Each ws In Worksheets
If ws.Name = Nom Then
Call MsgBox("La feuille avec ce nom existe déja.", vbCritical, "Impossible de créer une feuille")
Exit Sub
End If
Next ws
Sheets.Add , Sheets(Worksheets.Count)
ActiveSheet.Name = Nom
Sheets("Model").Select.Copy
Sheets(Nom).Select.Paste
End Sub


Malheureusement, ça ne fonctionne pas...
Ca créé bien la fiche avec le bon nom, mais une fiche vide, pas avec mon model....

merci de m'aider, je perd un temps fou...

ciao
@+

 

[kjin]

Re : copie d'une feuille model + chgt d'une donnée.

bonjour et bienvenue,
Utilise les balises pour le code (# dans le menu)

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim Nom As String, ws As Worksheet
If Target.Column <> 1 Or Target = "" Then Exit Sub
Nom = Target
For Each ws In Worksheets
If ws.Name = Nom Then
MsgBox "La feuille avec ce nom existe déja.", vbCritical, "Impossible de créer une feuille"
Exit Sub
End If
Next ws
Cancel = True
Sheets("Model").Copy after:=Sheets(Worksheets.Count)
With ActiveSheet
    .Name = Nom
    .Range("A1") = Nom
End With

End Sub

A+
kjin

 

[begastor]

Re : copie d'une feuille model + chgt d'une donnée.

Extra !!!
J'adore ces forum d'entraide, c'est beau !

merci Kjin, bonne journée à toi.

Begastor.

 

[VINCEGR]

Re : copie d'une feuille model + chgt d'une donnée.

bonjour begastor, kjin,
super comme fonction
merci
VinceGr

 

[begastor]

Re : copie d'une feuille model + chgt d'une donnée.

J'ai une question subsidiaire:

Ma feuille "model" est protégée en écriture, quelle code ajouter pour que la copie de la feuille ne le soit plus ?

merci
Ciao

 

[Guiv]

Re : copie d'une feuille model + chgt d'une donnée.

Bonjour à tous,
Puisque kjin est déconnecté:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim Nom As String, ws As Worksheet
If Target.Column <> 1 Or Target = "" Then Exit Sub
Nom = Target
For Each ws In Worksheets
If ws.Name = Nom Then
MsgBox "La feuille avec ce nom existe déja.", vbCritical, "Impossible de créer une feuille"
Exit Sub
End If
Next ws
Cancel = True
Sheets("Model").Copy after:=Sheets(Worksheets.Count)
With ActiveSheet
    [B][COLOR="Red"].Unprotect[/COLOR][/B]
    .Name = Nom
    .Range("A1") = Nom
End With

End Sub

Cordialement,
Guiv

 

[begastor]

Re : copie d'une feuille model + chgt d'une donnée.

impec merci beaucoup !!!

j'aurai un truc un peu plus complexe à vous soumettre demain...

bonne soirée.

merci encore.

Ciao

 

[begastor]

Re : copie d'une feuille model + chgt d'une donnée.

Bonjour,

ma demande du jour s'inscrit dans la continuité de celle d'hier.
lorsque je double clic en colonne "A" sur un nom de ma feuille "liste", je créé une autre feuille "model" dont le nom est le nom sur lequel j'ai cliqué. ensuite, ce nom se copie en case "B3" de cette nouvelle fiche.

Je souhaite:
que le prénom qui se trouve en colonne "B" à coté de celle dans laquelle je clique se retrouve en case B5 de la nouvelle feuille...
et que la date de naissance qui se trouve en colonne "C" se retrouve en case "N3"

Est-ce que quelquechose comme ça fonctionnerai ?
par contre, je ne connais pas la syntaxe...

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim Nom As String, ws As Worksheet
If Target.Column <> 1 Or Target = "" Then Exit Sub
Nom = Target
[COLOR="Red"]Prénom = Target + 1  ??? [COLOR="RoyalBlue"](pour dire que c'est la case d'a coté de celle ou j'ai double cliqué...)[/COLOR]
Date = Target + 2 ???[/COLOR]
For Each ws In Worksheets
If ws.Name = Nom Then
MsgBox "La feuille avec ce nom existe déja.", vbCritical, "Impossible de créer une feuille"
Exit Sub
End If
Next ws
Cancel = True
Sheets("Model B").Copy after:=Sheets(Worksheets.Count)
With ActiveSheet
    .Name = Nom
    .Range("B3") = Nom
[COLOR="red"]    .Range("B5") = Prénom
    .Range("N3") = Date[/COLOR]
End With

End Sub

Merci beaucoup pour votre aide.
Bonne journée;

Ciao

 

[begastor]

Re : copie d'une feuille model + chgt d'une donnée.

je me suis débrouillé yes !!!

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim Nom As String, ws As Worksheet

If Target.Column <> 1 Or Target = "" Then Exit Sub
Nom = Target
Prénom = Cells(Target.Row, Target.Column + 1)
DDN = Cells(Target.Row, Target.Column + 2)

For Each ws In Worksheets
If ws.Name = Nom Then
MsgBox "La feuille avec ce nom existe déja.", vbCritical, "Impossible de créer une feuille"
Exit Sub
End If
Next ws
Cancel = True
Sheets("Model B").Copy after:=Sheets(Worksheets.Count)
With ActiveSheet
    .Name = Nom
    .Range("B3") = Nom
    .Range("B5") = Prénom
    .Range("N3") = DDN
End With

End Sub

 

[Guiv]

Re : copie d'une feuille model + chgt d'une donnée.

Bonjour,
Tu peux aussi utiliser la fonction "Offset":

Prénom=Target.Offset(0,1)
DDN=Target.Offset(0,2)

Le 0 est le nombre de ligne de décalage et le 1 (ou 2) le nombre de colonnes de décalage. Aide disponible en sélectionnant le mot Offset et F1.
Bonne journée,
Guiv