Copie d'image sur internet

Private Sub CommandButton3_Click()
'testé avec WinXP & Excel2002
'nécéssite d'activer la référence Microsoft HTML Objects Library
'nécéssite d'activer la référence Microsoft Internet Controls
Dim IE As InternetExplorer
Dim maPageHtml As HTMLDocument
Dim imgHtml As HTMLImg
Dim i As Integer
Dim Shp As Shape
Dim Fichier As String
Dim Largeur As Single, Hauteur As Single, VertiPos As Single
 
VertiPos = 20
 
Set IE = CreateObject("InternetExplorer.Application")
IE.Visible = True
 
IE.navigate "[URL]https://www.excel-downloads.com/forums/[/URL]"
    Do Until IE.readyState = READYSTATE_COMPLETE
    DoEvents
Loop 'attend la fin du chargement pour continuer la procedure
 
Set maPageHtml = IE.Document
'compte le nombre d'images dans la page
MsgBox "nombre d'images dans la page : " & maPageHtml.images.Length
 
'boucle sur les images
For i = 0 To maPageHtml.images.Length - 1
    Set imgHtml = maPageHtml.images.Item(i)
 
    Fichier = imgHtml.src 'adresse image
    Largeur = imgHtml.Width 'largeur image
    Hauteur = imgHtml.Height 'hauteur image
 
    'expression.AddPicture
    '(FileName, LinkToFile, SaveWithDocument, Left, Top, Width, Height)
    Set Shp = Feuil1.Shapes.AddPicture(Fichier, msoFalse, msoCTrue, _
        50, VertiPos, Largeur, Hauteur)
 
    VertiPos = VertiPos + Hauteur + 20
    Set Shp = Nothing
Next i
End Sub