Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

Compter dans une plage le nombre de fois qu'un chiffre apparait avec une condition

Créer une discussion
  • Initiateur de la discussion Initiateur de la discussion syl0038
  • Date de début Date de début

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

S'inscrire
S

syl0038

XLDnaute Junior
Bonjour à tous,
Je n'arrive pas à réaliser et à trouver une formule qui m'aiderait à :
Compter dans une plage le nombre de fois qu'un chiffre apparait avec une condition.

Voivi mes données :
AV 100
AV 100
AV 200
PSS 150
PSS 150
PSS 150
BSS 300
BSS 400
BSS 500
BSS 600

J'aimerais avoir comme réponse AV = 2 PSS =1 BSS = 4.

J'ai essayé avec cette formule =SUMPRODUCT(1/COUNTIF(B1:B10,B1:B10)) mais je n'arrive pas à mettre comme condition AV PSS et BSS.

Merci de m'aider,
En vous remerciant!

Syl
 

Pièces jointes

Trier par date Trier par votes
Re : Compter dans une plage le nombre de fois qu'un chiffre apparait avec une conditi

Bonjour,


Occurences uniques avec condition


=NB(1/FREQUENCE(SI(critere=E12;EQUIV(ch;ch;0));LIGNE(INDIRECT("1:"&LIGNES(ch)))))
Valider avec maj+ctrl+entrée

ch =$B$1:$B$10
critere =$A$1:$A$10

Si cellules vides:

=NB(1/FREQUENCE(SI((critere=E12)*(ch<>"");EQUIV(ch;ch;0));LIGNE(INDIRECT("1:"&LIGNES(ch)))))


JB
 

Pièces jointes

Dernière édition:
Vote positif 0 Vote négatif
Re : Compter dans une plage le nombre de fois qu'un chiffre apparait avec une conditi

Bonjour,
à rentrer en E13, valider en matriciel (Ctrl, Maj et entrée) et à tirer vers la droite :
Code: 
=NB(SI($A1:$A10=E12;SI(EQUIV($B1:$B10;$B1:$B10;0)=LIGNE(INDIRECT("1:"&LIGNES($B1:$B10)));LIGNE($B1:$B10))))
A+
 
Vote positif 0 Vote négatif
Re : Compter dans une plage le nombre de fois qu'un chiffre apparait avec une conditi

Bonjour @ tous,
une autre plus courte, pour le fun 😱,
Sélectionner la plage E13:G13,
Copier/Coller cette formule dans la barre des formules,
Code: 
=TRANSPOSE(FREQUENCE(SI(FREQUENCE(B1:B10;B1:B10);EQUIV(A1:A10;E12:G12;0));{1;2}))
@ valider par Ctrl+Maj+Entree
@ micalement
 
Vote positif 0 Vote négatif
Re : Compter dans une plage le nombre de fois qu'un chiffre apparait avec une conditi

Bonsoir @ tous,
J'ai essayé avec cette formule =SUMPRODUCT(1/COUNTIF(B1:B10,B1:B10)) mais je n'arrive pas à mettre comme condition AV PSS et BSS.
Cliquez pour agrandir...
Ok, du fait que tes données sont triées sur la colonne A,
en E13,
Code: 
=SOMMEPROD(1/NB.SI(DECALER($B1;EQUIV(E12;$A1:$A10;0)-1;;NB.SI($A1:$A10;E12));DECALER($B1;EQUIV(E12;$A1:$A10;0)-1;;NB.SI($A1:$A10;E12))))
@ valider par Simple Entree
@ tirer vers la droite
@ micalement
 
Vote positif 0 Vote négatif
Re : Compter dans une plage le nombre de fois qu'un chiffre apparait avec une conditi

Bonjour,
l Le problème avec l'utilisation de SOMMEPROD(1/NB.SI( est que ce n'est pas fiable dans ce type de cas...

Par exemple, remplace tous les PPS par des AV et tu verras que
Code: 
=SOMMEPROD(1/NB.SI(DECALER($B1;EQUIV(E12;$A1:$A10;0)-1;;NB.SI($A1:$A10;E12));DECALER($B1;EQUIV(E12;$A1:$A10;0)-1;;NB.SI($A1:$A10;E12))))
ramène #NA.

Concernant ton essai
Code: 
=SUMPRODUCT(1/COUNTIF(B1:B10,B1:B10))
, on peut éventuellement tester
Code: 
=SOMMEPROD(1/NB.SI($B$1:$B$10;$B$1:$B$10)*($A$1:$A$10=E12))
mais là encore problème (cela peut donner des nombres avec virgule).

On peut éventuellement tester
Code: 
=ARRONDI.SUP(SOMMEPROD(1/NB.SI($B$1:$B$10;$B$1:$B$10)*($A$1:$A$10=E12));0)
qui fonctionne sur quelques tests vite faits, mais à vérifier plus avant.
A+
 
Vote positif 0 Vote négatif
Re : Compter dans une plage le nombre de fois qu'un chiffre apparait avec une conditi

Bonjour @ tous,
Salut David,
Oui c'est sur car y aura pas de PSS en colonne A, on peut le gérer avec =SIERREUR(Formule;0) et comme ça on est sur de sa fiabilité...
Amicalement
 
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.
Rejoins nos membres "Supporter XLD" et booste ton expérience Excel !
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

S
  • Question Question
XL 2021 Compter le nombre de fois qu'une tranche d'heures apparait dans une plage de cellules
Réponses
3
Affichages
608
Sanni
S
R
  • Résolu(e)
XL 2016 Compter le nombre de Chiffre suivi de lettre dans une cellule
Réponses
6
Affichages
924
Rabeto
R
S
  • Résolu(e)
XL 2016 Comment compter le nombre de valeur lorsqu'on applique un filtre sans compter le nombre de ligne
2
Réponses
17
Affichages
1 K
TooFatBoy
M
  • Question Question
XL 2019 compter le nombre de mot dans un tableau excel
Réponses
2
Affichages
566
melltel
M
M
  • Résolu(e)
XL 2019 Comment Compter le nombre d'occurrences d'un mot dans une colonne
Réponses
6
Affichages
822
melltel
M
  • Question Question
XL 2016 formule pour compter le nombre de fois qu'apparait une croix au regard d'un nom
Réponses
3
Affichages
1 K
alouette30
L
  • Résolu(e)
XL pour MAC compter le nombre de cellules avec condition
Réponses
2
Affichages
984
lopmsite
L
K
  • Question Question
Power BI Comment créer une mesure qui compte le nombre de fois qu'il y a un chiffre spécifique dans une colonne. Power BI
Réponses
2
Affichages
3 K
kondabalo
K
S
  • Question Question
XL 2019 Compter le nombre de sélection de contenu différent dans une listebox
Réponses
2
Affichages
802
SPGoder
S
G
  • Question Question
XL 2010 Compter le nombre de virgules dans une liste de nombres
Réponses
4
Affichages
2 K
GilTho
G
O
  • Question Question
Compter le nombre d'occurences dans plage dynamique
Réponses
2
Affichages
1 K
OOLIVE
O
M
  • Question Question
Compter le nombre de dates uniques dans une colonne
Réponses
11
Affichages
5 K
Staple1600
I
  • Question Question
XL 2013 compter le nombre de fois dans un tableau actualisé
Réponses
3
Affichages
1 K
ivan972
I
I
  • Question Question
XL 2013 compter le nombre de fois dans un tableau actualisé
Réponses
1
Affichages
865
vgendron
M
  • Question Question
XL pour MAC Additionner le nombre de fois qu'un nom est saisi dans plusieurs feuilles
Réponses
12
Affichages
1 K
JCGL
M
  • Question Question
XL 2013 compter le nombre de chaîne caractere dans une colonne
Réponses
5
Affichages
2 K
Marco65
M
M
  • Question Question
Compter une chaîne de caractère connu avec une condition
Réponses
2
Affichages
781
Marco65
M
C
  • Question Question
XL 2013 Nombre de cellules remplies au sein d'une plage (complexe!)
Réponses
4
Affichages
1 K
clemclem
C
A
  • Question Question
Compter le nombre de valeurs différentes selon une condition sur une autre colonne
2
Réponses
16
Affichages
3 K
cyberdico
C
D
  • Question Question
connaitre le nombre de fois qu'une donnée apparait dans une feuille
Réponses
1
Affichages
3 K
Compte Supprimé 979
C
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…