comment simplifier cette macro ?

[kinel]

bonjour à tous

suite aux conseils de certains membres du forum je souhaite simplifier cette macro que j'ai créée par l'enregistreur

Sub commande12()
Sheets("Liste").Select
Range("A5😀142").Select ( le😀 = ": D" sans espace)
ActiveWindow.SmallScroll Down:=-153
Range("A5😀142,Q5:Q142").Select
Range("Q5").Activate
Selection.Copy
Sheets("Bon de Commande").Select
Application.DisplayFullScreen = True
Range("C3").Select
ActiveSheet.Paste
Application.CutCopyMode = False
Range("B2:G143").AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:= _
Range("I1:I2"), Unique:=False
ActiveWindow.SmallScroll Down:=-54
Range("G3:G141").Select
Selection.FormatConditions.Delete
Range("B1:H1").Select
End Sub

merci de vos conseils

Kinel

 

[Titoy]

Re : comment simplifier cette macro ?

SAlut KINEL
DAns un premier temps commence par supprimer les
ActiveWindow.SmallScroll Down:
C'est quand ton ecran descent il met une ligne de code pour rien.
ensuite le reste je sais pas lol 😛

A+

Sub commande12()
Sheets("Liste").Select
Range("A5142").Select ( le = ": D" sans espace)
Range("A5142,Q5:Q142").Select
Range("Q5").Activate
Selection.Copy
Sheets("Bon de Commande").Select
Application.DisplayFullScreen = True
Range("C3").Select
ActiveSheet.Paste
Application.CutCopyMode = False
Range("B2:G143").AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:= _
Range("I1:I2"), Unique:=False
Range("G3:G141").Select
Selection.FormatConditions.Delete
Range("B1:H1").Select
End Sub

 

[kinel]

Re : comment simplifier cette macro ?

C'est déjà ça

merci Titoy

 

[alex67800]

Re : comment simplifier cette macro ?

Bonjour kinel, Titoy,
Essai comme ceci:

Sub commande12()
Sheets("Liste").Select
Range("A5: D142,Q5:Q142").copy ( le = ": D" sans espace)
Sheets("Bon de Commande").Range("C3").Select
ActiveSheet.Paste
Application.CutCopyMode = False
Range("B2:G143").AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:= _
Range("I1:I2"), Unique:=False
Range("G3:G141").FormatConditions.Delete
Range("B1:H1").Select 'Pourquoi cette selection?
End Sub

Edit: Dans une macro les Select ne sont généralement pas nécessaire et alourdissent inutilement ton code. Tu pourrais donc remplacer la première ligne comme ceci:

Sheets("Liste").Range("A5: D142,Q5:Q142").copy ( le = ": D" sans espace)

 

[vbacrumble]

Re : comment simplifier cette macro ?

Bonjour tous

kinel
Peux-tu tester ce code VBA,stp ,

Sub commande12()
Dim f As Worksheet, f2 as Worksheet, source As Range, dest As ange
Set f = Sheets("Liste")
Set f2 = Sheets("Bon de Commande")
    With f
        Set source = .Range("A5:D142,Q5:Q142")
        Set dest = f2.Range("C3")
    source.Copy dest
    End With
    With f2
        .Range("B2:G143").AdvancedFilter Action:=xlFilterInPlace, _
        CriteriaRange:= _
        .Range("I1:I2"), Unique:=False
        .Range("G3:G141").FormatConditions.Delete
    End With
End Sub

 

[nolich]

Re : comment simplifier cette macro ?

Bonjour kinel, Titoy, alex67800 et vbacrumble, bonjour à toutes et à tous,

Pas sans les mains, mais sans les variables 🙂

J'ai supprimé le DisplayFullScreen mais à toi de voir.

Sub commande12()
  
  Sheets("Liste").Range("A5:D142,Q5:Q142").Copy Destination:=Sheets("Bon de Commande").Range("C3")
  Sheets("Bon de Commande").Activate
  With ActiveSheet
    .Range("B2:G143").AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:= _
                  Range("I1:I2"), Unique:=False
    .Range("G3:G141").FormatConditions.Delete
    .Range("B1:H1").Select
  End With
End Sub

Cordialement,
Lio

EDIT : vbacrumble, ta proposition est fort élégante 🙂

 

[kinel]

Re : comment simplifier cette macro ?

bonjour et merci à tous

je crois bien avoir retenu un petit morceau de chacune de vos propositions

sur la base de vbacrumble

j'ai juste ajouté une petite ligne qui ouvre la feuille bondecommande
pour visualiser le bon avant de l'imprimer

c'est beaucoup plus rapide que mon enregistrement "d'excelien en herbe ! "

merci encore de vos réponses

Kinel