XL 2013 comment Identifier le type Rows où columns

[patricktoulon]

bonjour à tous
comment peut on identifier le type Rows ou Columns avec un argument rows ou columns
j'explique
j'ai une fonction dans la quelle j'injecte un argument rng.rows ou rng .columns
je voudrais identifier le type d'object et non "Range"

Sub test()
Dim rng As Range

Set rng = [A1:A20]
mafiontion rng, rng.Rows

Set rng = [A1:H10]
mafiontion rng, rng.Columns
End Sub

Function mafonction(r As Range, RowColumns)
MsgBox TypeName(RowColumns)
End Function

 

[Dranreb]

Bonsoir.
Il ne semble-t-y avoir de propriété qui l'indiquent, mais il devrait être possible d'analyser la structure de l'item 1 du RowColumns en interrogeant son Columns.Count et son Rows.Count

 

[patricktoulon]

re
bonsoir @Dranreb j'ai pensé à un truc comme ça mais c'est pas 100% valable
notement pour une plage de ligne et colonne du même nombre
j'ai essayé aussi une variable tableau temporaire et test du ubound(tbl,,2) mais là encore choux blanc casiment pour la même raison
je ne pense pas que ce soit possible je vais faire autrement

 

[patricktoulon]

re
hah!! peut être que si finalement
le resultat est bizarre mais bon j'ai recommencé 10 fois et ca semble être un point de comparaison

Sub test()
Dim rng As Range

Set rng = [A1:A20]
Mafonction rng, rng.Rows

Set rng = [A1:A20]
Mafonction rng, rng.Columns
End Sub

Function Mafonction(r As Range, RowColumns As Range)
MsgBox RowColumns(1).Cells.Count


End Function

 

[patricktoulon]

bon ben ça semble être bon
je pense avoir fini par trouver

Sub test()
Dim rng As Range

Set rng = [A1:a20]
Mafonction rng, rng.Rows

Set rng = [A1:a20]
Mafonction rng, rng.Columns
End Sub

Function Mafonction(r As Range, RowColumns As Range)
x = RowColumns(1).Address = RowColumns.Rows(1).Address
MsgBox Array("colonnes", "lignes")(Abs(x))
End Function

testé avec différentes plages de cellules

 

[Dranreb]

.Cells.Count ça ne va pas aider pour une plage carrée ! C'est soit le Rows.Count soit le Columns.Count > 1 qui serait intéressant.

 

[patricktoulon]

on c'est croisé je pense
j'ai trouvé la solution post #5
il fallait aller la chercher celle là 🤣

 

[Dranreb]

Mais pourquoi tester l'adresse ?
Mon idée c'était que si c'est un Range.Rows son Item(1).Rows.Count = 1 et pas son Item(1).Columns.Count et
si c'est un Range.Columns son Item(1).Columns.Count = 1 et pas son Item(1).Rows.Count.

 

[patricktoulon]

re
tu a tester avec une plage avec le même nombre de ligne et de colonnes ?

 

[Dranreb]

Non, je n'ai pas testé, mais même si elle est carrée, avec un For Each In on récupère des lignes si c'est un .Rows et des colonnes si c'est un .Columns, alors je pensais que c'était pareil avec son item 1, et donc qu'il pouvait avoir plusieurs lignes mais une seule colonne ou l'inverse.

 

[patricktoulon]

cet exemple t'aidera mieux a comprendre
une plage de 10 lignes et 10 colonnes

Sub test()
    Dim rng As Range

    Set rng = [A1:j10]
    Mafonction rng, rng.Rows

    Set rng = [A1:j10]
    Mafonction rng, rng.Columns
End Sub

Function Mafonction(r As Range, RowColumns As Range)
    Dim texte As String

    texte = " RowColumns(1).Address = " & RowColumns(1).Address & " " & RowColumns(1).Cells.Count & " cellules" & vbCrLf & vbCrLf

    texte = texte & " RowColumns.Rows(1).Address = " & RowColumns.Rows(1).Address & " " & RowColumns.Rows(1)(1).Cells.Count & " cellules" & vbCrLf & vbCrLf

    x = RowColumns(1).Address = RowColumns.Rows(1).Address

    texte = texte & "Résultat : " & Array("colonnes", "lignes")(Abs(x))

    MsgBox texte

End Function

l'astuce réside dans
RowColumns.Rows(1) .address et RowColumns(1).address
par le cells.count je peux avoir la même chose sur une plage egale en nombre de lignes et colonnes
par les adresse là c'est différent
😉

 

[Dranreb]

Ça ne marche pas avec les Columns.Count et Rows.Count ?

 

[patricktoulon]

ben non justement
ou je pourrais-je bien faire la difféernce avec un count que ce soit des cells ou des rows ou des columns
si j'ai 10 lignes et 10 colonnes par exemple comme on peut le voir dans le msgbox
j'ai tout le temps 10 cellules
sauf que si on teste les adresses ce ne sont pas les mêmes 😉

la seule faille dans cette méthode c'est si j'injecte un range de une seule cellule 🤣 🤣 🤣

 

[Dranreb]

Bon, je me suis décidé à tester, et, désolé mais ça marche exactement comme je le souhaitais :

Option Explicit
Sub Test()
   Dim Rng As Range
   Set Rng = [A1:J10]
   MsgBox Mafonction(Rng)
   MsgBox Mafonction(Rng.Rows)
   MsgBox Mafonction(Rng.Columns)
   End Sub
Function Mafonction(ByVal Rng As Range) As String
   Dim LMax As Long, CMax, L1 As Long, C1 As Long
   LMax = Rng.Rows.Count
   CMax = Rng.Columns.Count
   L1 = Rng(1).Rows.Count
   C1 = Rng(1).Columns.Count
   Mafonction = Choose(1 - 2 * (L1 > 1) - (C1 > 1), _
      LMax * CMax & " cells", _
      LMax & " lignes de " & CMax, _
      CMax & " colonnes de " & LMax)
   End Function

 

[patricktoulon]

re
oui je suppose que l'on peut encore en trouver d'autre de méthodes
mais reconnais que tu tricote
alors que je le fait en une ligne

msgbox Array("colonnes", "lignes")(Abs(RowColumns(1).Address = RowColumns.Rows(1).Address))