Microsoft 365 Comment extraire les noms d'une cellule Excel contenant du texte

[desto]

Bonjour à tous,
Je viens par ce canal vous demander si quelqu'un peu m'indiquer la façon dont je pourrai extraire les noms et prénoms de la colonne T du fichier ci joint.
L'objectif est de pouvoir ressortir les noms afin de les utiliser pour des vérifications.
Par Exemple sur la ligne T2 j'ai le texte suivant : "TR EXP//000//202//ABIAKWEH KINGSLEY//SABO BINTOU".
Je voudrais pouvoir sortir "ABIAKWEH KINGSLE" dans une colonne et "SABO BINTO" dans une autre colonne.
Avec la formule STXT j'ai du mal car tous les noms n'ont pas la même longueur et n'occupent pas les même positions

 

[xUpsilon]

Bonjour,

Dans "Données", cliquer sur "Convertir", puis Séparateurs : Autre : "/".
Cliquer "Interpréter des séparateurs identiques consécutifs comme uniques".

Bonne journée,

 

[danielco]

Bonjour à tous,
Je viens par ce canal vous demander si quelqu'un peu m'indiquer la façon dont je pourrai extraire les noms et prénoms de la colonne T du fichier ci joint.
L'objectif est de pouvoir ressortir les noms afin de les utiliser pour des vérifications.
Par Exemple sur la ligne T2 j'ai le texte suivant : "TR EXP//000//202//ABIAKWEH KINGSLEY//SABO BINTOU".
Je voudrais pouvoir sortir "ABIAKWEH KINGSLE" dans une colonne et "SABO BINTO" dans une autre colonne.
Avec la formule STXT j'ai du mal car tous les noms n'ont pas la même longueur et n'occupent pas les même positions

Bonjour à tous,
Essaie :

=INDEX(FRACTIONNER.TEXTE(T2;"//");4)
et
=INDEX(FRACTIONNER.TEXTE(T2;"//");5)

à recopier vers le bas.
Daniel

 

[danielco]

Ou plutôt :

=INDEX(FRACTIONNER.TEXTE(T2;"//");NBVAL(FRACTIONNER.TEXTE(T2;"//"))-1)
et
=INDEX(FRACTIONNER.TEXTE(T2;"//");NBVAL(FRACTIONNER.TEXTE(T2;"//")))

Daniel

 

[R@chid]

Bonjour @ tous,
Sous Excel pour Microsoft 365, en U2 :

=CHOISIRCOLS(FRACTIONNER.TEXTE($T2;"//";;1);(SEQUENCE(;2)-1)+(NBCAR(T2)-NBCAR(SUBSTITUE(T2;"//";)))/2)

@ tirer vers le bas


Bien cordialement

 

[Etoto]

Hello,

J'écris pour informer que si la fonction FRACTIONNER.TEXTE ne fonctionne pas sur ton Office 365 c'est parce qu'elle est pas encore dans toutes les versions, je suis sous 365 au travail sans l'avoir.

 

[danielco]

Est-ce que tu as TEXTE.APRES ?

 

[Etoto]

Est-ce que tu as TEXTE.APRES ?

Non, ce ne sont pas des fonctions seulement disponible sur Office 365 Insider ?

 

[danielco]

Non, je ne suis pas insider, bizarre.

 

[danielco]

Non, ce ne sont pas des fonctions seulement disponible sur Office 365 Insider ?

Et pourtant, oui, elles sont marquées insider bêta...

 

[Etoto]

Non, je ne suis pas insider, bizarre.

C'est possible que l'entreprise dans laquelle je travaille ne mette pas à jour Office directement aussi. J'ai 365 for entreprise.

 

[danielco]

Essaie :

=INDEX(TRANSPOSE(FILTRE.XML("<M><R>"&SUBSTITUE(T2;"//";"</R><R>")&"</R></M>";"//R"));NBVAL(TRANSPOSE(FILTRE.XML("<M><R>"&SUBSTITUE(T2;"//";"</R><R>")&"</R></M>";"//R")))-1)
et
=INDEX(TRANSPOSE(FILTRE.XML("<M><R>"&SUBSTITUE(T2;"//";"</R><R>")&"</R></M>";"//R"));NBVAL(TRANSPOSE(FILTRE.XML("<M><R>"&SUBSTITUE(T2;"//";"</R><R>")&"</R></M>";"//R"))))

 

[R@chid]

Bonjour @ tous,

C'est possible que l'entreprise dans laquelle je travaille ne mette pas à jour Office directement aussi. J'ai 365 for entreprise.

Vous pouvez essayer de le mettre à jour et vérifier, sinon il faudrait que l'admin mette à jour la suite Microsoft 365.

Bien cordialement

 

[Etoto]

Bonjour @ tous,

Vous pouvez essayer de le mettre à jour et vérifier, sinon il faudrait que l'admin mette à jour la suite Microsoft 365.

Bien cordialement

Je vais devoir attendre que les administrateurs mettent à jour, je n'ai aucuns droit dessus. Pas grave, j'ai Insider chez moi

 

[danielco]

HS. Est-ce que vous savez comment vérifier si on est insider ?