Microsoft 365 ComboBox : Est-il possible d'agrandir l'affichage ?

[Usine à gaz]

Bonjour à toutes et à tous,
Je vous souhaite une belle journée

Je me tourne une nouvelle fois vers nos ténors car je n'arrive pas à grossir l'affichage de ma ComboBox,
Est-ce possible ? :

Sub Laurent()
    Dim WS As Worksheet
    Set WS = ActiveSheet
    Dim tbl() As Variant
    tbl = Array("Metropole 33", "988 Nouvelle-Calédonie  687", "987 Polynésie française 689", _
    "974 La Réunion  262", "973 Guyane 594", "972 Martinique 596", "971 Guadeloupe 590", 0) '"",

    ' Les valeurs
    ReDim Preserve tbl(UBound(tbl) - 1)
    ' La Liste Box
    Dim oCombo As OLEObject
    Dim L As Single, H As Single, T As Single, W As Single
    L = ActiveCell.Offset(, 1).Left   '<-- position horizontale
    T = ActiveCell.Top  '<-- position verticale
    W = 202 '<-- largeur
    H = 15 '<-- hauteur
    ' Si la liste existe
    For Each oCombo In WS.OLEObjects
        If oCombo.progID = "Forms.ComboBox.1" Then
            If oCombo.Name = "Combo1" Then
                oCombo.Delete
            End If
        End If
    Next
    ' Creation de la liste de choix
    Set oCombo = WS.OLEObjects.Add(ClassType:="Forms.ComboBox.1", Left:=L, Top:=T, Width:=W, Height:=H)
    With oCombo
    .Name = "Combo1" '<-- nom du Combobox
    .Object.List() = tbl '<-- exemple de chargement des données
    .Activate
    .Object.DropDown
    End With
    Set oCombo = Nothing
End Sub

Je joins un fichier test et je continue mes recherches.
Je vous remercie pour votre aide,
Amicalement,
lionel

 

[Dranreb]

Bonjour.
Ne pouvez vous définir ça une fois pour toutes dans la fenêtre de propriétés ?
Remarque: vous devriez peut-être d'abord simplifier tout ça.

 

[ChTi160]

Bonjour Lionel
Bonjour le Fil
peut être en Augmentant La taille du Texte de ton Combobox !
Bonne Journée
Jean marie

 

[Dranreb]

Comme ça, là, déjà ce serait beaucoup plus simple, non ? :

Option Explicit
Private Sub Worksheet_Activate()
   [A1].Select
   End Sub
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
   If Not Application.Intersect(Target, Range("F6:F15")) Is Nothing Then
      Cancel = True
      With Me.Combo1
         .List = Array("Metropole 33", "988 Nouvelle-Calédonie  687", "987 Polynésie française 689", _
            "974 La Réunion  262", "973 Guyane 594", "972 Martinique 596", "971 Guadeloupe 590")
         .Left = Target.Offset(, 1).Left   '<-- position horizontale
         .Top = Target.Top '<-- position verticale
         .Width = 202 '<-- largeur
         .Height = Target.Height '<-- hauteur
         .Visible = True
         .DropDown
         End With
      End If
   End Sub
Private Sub Combo1_Change()
   If Combo1.MatchFound Then
      Combo1.Visible = False
      ActiveCell.Value = Left$(Combo1.Text, 3) & Right$(ActiveCell.Value, 9)
      Combo1.Text = ""
      [A1].Select
      End If
   End Sub

 

[Usine à gaz]

Bonjour Dranreb
Merci pour le code .... mais ça beugue :

lionel

 

[Dranreb]

Recrée la ComboBox et ne la supprime plus.

 

[Usine à gaz]

Bonjour Lionel
Bonjour le Fil
peut être en Augmentant La taille du Texte de ton Combobox !
Bonne Journée
Jean marie

Bonjour Jean-Marie,

J'ai tenté à plusieurs reprises de changer dans les propriétés mais comme le Combobox est supprimé avec utilisation et recréé ensuite, forcément ça disparait lol

 

[Usine à gaz]

Recrée la ComboBox et ne la supprime plus.

OK, je vois comme ça, Merci

 

[ChTi160]

Re
J'ai aussi pensé à cela le masquer plutôt que de le supprimer
Bonne journée
Jean marie

 

[Usine à gaz]

OK, je vois comme ça, Merci

Re @Dranreb

Merci, c'est "presque nickel",
Il y a un souci sur le code " ActiveCell.Value = Left$(Combo1.Text, 3) & Right$(ActiveCell.Value, 9)"
En fait il faudrait :

lionel

 

[Dranreb]

Remplace Left$(Combo1.Text, 3) par Right$(Combo1.Text, 3)

 

[Usine à gaz]

Nickel Merci ... j'aurais le voir celui-là
Merci à toi

 

[ChTi160]

Re
bien que résolu
pour imager ce que j'ai compris!
je n'ai pas traité la Modification du Numéro dans la Liste !tu as la solution .
Bonne fin de Journée
Jean marie

 

[ChTi160]

Re
une autre vidéo !
avec mise a jour du numéro !

Private Sub Worksheet_Activate()
Cancel = False
[a1].Select
End Sub

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Application.Intersect(Target, Range("f6:f15")) Is Nothing Then
Cancel = True
Laurent
End If
End Sub

Private Sub Combo1_Change()
    Dim WS As Worksheet
    Dim Indic As String
    Set WS = ActiveSheet
    
    Set oCombo = ActiveSheet.OLEObjects("Combo1")
         Indic = Right(oCombo.Object.Text, 3) & Right(ActiveCell, 9)
                ActiveCell.Value = Indic
                  oCombo.Visible = False
 Set oCombo = Nothing
[a1].Select
End Sub
Sub Laurent()
   Dim tbl() As Variant
    ' Les valeurs
    Dim L As Single, H As Single, T As Single, W As Single
   Set oCombo = ActiveSheet.OLEObjects("Combo1")
  
    tbl = Array("Metropole 33", "988 Nouvelle-Calédonie  687", "987 Polynésie française 689", _
    "974 La Réunion  262", "973 Guyane 594", "972 Martinique 596", "971 Guadeloupe 590") '"",
  
    L = ActiveCell.Offset(, 1).Left   '<-- position horizontale
    T = ActiveCell.Top  '<-- position verticale
    W = 302 '<-- largeur
    H = 1 '<-- hauteur
    With oCombo
         .Visible = True
         .Left = L
         .Top = T
         .Width = W
         .Height = H
         .Object.Font.Name = "Calibri"
         .Object.FontSize = 24
         .Object.List() = tbl '<-- exemple de chargement des données
         .Activate
         .Object.DropDown
    End With
    Set oCombo = Nothing
End Sub

Jean marie

 

[Usine à gaz]

Re
bien que résolu
pour imager ce que j'ai compris!
je n'ai pas traité la Modification du Numéro dans la Liste !tu as la solution .
Bonne fin de Journée
Jean marie

ça à l'air super Jean-Marie ... si tu as le fichier, je prends quand même
Dsl, idiot que je suis : je prends le code