XL 2019 ComboBox dans des cellules différenciées avec la même liste

[hemardjean]

Bonjour le forum

Je me tourne à nouveau vers vous, peut-on avec le code suivant utiliser La même ComboBox avec la même liste dans des cellules différenciées ex : en c2 et en e2.

J'ai essayé plusieurs façons mais aucune ne fonctionne.

(Code issu de l'excellent site de M. boisgontierj)


Private Sub Worksheet_SelectionChange(ByVal Target As Range)

If Not Intersect([c2:c2], Target) Is Nothing And Target.Count = 1 Then

a = Sheets("BD").Range("listeVilles").Value

Me.ComboBox1.List = a

Me.ComboBox1.Height = Target.Height + 3

Me.ComboBox1.Width = Target.Width

Me.ComboBox1.Top = Target.Top

Me.ComboBox1.Left = Target.Left

Me.ComboBox1 = Target

Me.ComboBox1.Visible = True

Me.ComboBox1.Activate

'Me.ComboBox1.DropDown ' ouverture automatique au clic dans la cellule

Else

Me.ComboBox1.Visible = False

End If

End Sub



Merci d'avance pour votre aide

cordialement

 

[fanch55]

Bonjour,
Le code ci-dessous devrait convenir

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    With Me.ComboBox1
        If .Visible Then
            .Activate
            .Visible = False
        End If
        If Target.Address = "$C$2" Or Target.Address = "$E$2" Then
            .List = Sheets("BD").Range("listeVilles").Value
            .Height = Target.Height + 3
            .Width = Target.Width
            .Top = Target.Top
            .Left = Target.Left
            .Value = Target
            .Activate
            .Visible = True
            .DropDown ' ouverture automatique au clic dans la cellule
        End If
    End With
End Sub

 

[hemardjean]

Bonjour fanch55​

Merci pour ta réponse cela fonctionne avec les deux cellules proposé, j'ai essayé d'adapter ton code pour ajouter d'autres cellules au niveau de
If Target.Address = "$C$2" Or Target.Address = "$E$2" Then

en ajoutant :Or Target.Address = "$F$2"

mais la liste déroulante ne s'affiche pas il me manque sûrement un élément.
J'aurais dû préciser dans la question qu'il y aurait 24 listes déroulantes du même type mais elles ne sont pas côte à côte.

Merci de ta réponse
Bien cordialement.

 

[TooFatBoy]

Bonjour,

En reprenant ton code initial, je te propose ceci :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
'
Dim MesCellules As Range

    Set MesCellules = Range("C2,E2,G3,B5,E5")

    With Me.ComboBox1
        .Visible = False
        If Not Intersect(Target, MesCellules) Is Nothing And Target.Count = 1 Then
            .List = Sheets("BD").Range("listeVilles").Value
            .Height = Target.Height + 3
            .Width = Target.Width + 2
            .Top = Target.Top
            .Left = Target.Left
            .Value = Target
            .Activate
            .Visible = True
            .DropDown ' ouverture automatique au clic dans la cellule
        End If
    End With

End Sub

 

[fanch55]

With Me.ComboBox1
.Visible = False
If Not Intersect(Target, MesCellules) Is Nothing And Target.Count = 1 Then
....
.DropDown ' ouverture automatique au clic dans la cellule
End If
End With
End Sub
[/code]

Salut @Marcel32 ,
Comme il peut y avoir eu des dropdowns,
si tu te contentes de mettre le visible à false à chaque selection,
tu risques d'avoir des rémanences de listes .
Sinon l'intersect est le bon choix .

 

[TooFatBoy]

Comme il peut y avoir eu des dropdowns,
si tu te contentes de mettre le visible à false à chaque selection,
tu risques d'avoir des rémanences de listes .

Est-ce que tu peux,
s'il te plait,
m'expliquer un peu plus,
ce que cela veut dire ?

 

[hemardjean]

bonjour Marcel32, fanch55
je viens d'intégrer le code de Marce32 il fonctionne bien dans mon dossier test mais lorsque je l'intègre dans le dossier avec mes documents il me marque
"erreur de compilation type défini par l'utilisateur non défini"
pour plus de compréhension dans ma demande je vous rejoins le dossier.
Les cellules où je désire les listes sont situés en ligne 34, 39, 44, 51, et les colonnes A,F, J, N, R, V, AA.

Bien cordialement à tous les 2

 

[hemardjean]

toutes mes excuses j'ai oublié de joindre le fichier

 

[fanch55]

Est-ce que tu peux,
s'il te plait,
m'expliquer un peu plus,
ce que cela veut dire ?

Désolé, je voulais en faire un Gif pour te montrer, mais je n'ai plus le phénomène

 

[fanch55]

toutes mes excuses j'ai oublié de joindre le fichier

Erreur normale: pas de listevilles, pas de combobox1 , pas de feuilles Bd ...

 

[hemardjean]

j'ai remplacé listevilles et Bd par
.List = Sheets("planning et légumes").Range("liste").Value

mais rien ne s'affiche?

 

[TooFatBoy]

"erreur de compilation type défini par l'utilisateur non défini"

Est-ce que ta ComboBox s'appelle bien ComboBox1 ?


[edit]
Désolé, je n'avais pas lu au-delà de #7, donc pas vu #10.
Il n'y a effectivement aucune ComboBox dans ta feuille...
[/edit]

 

[TooFatBoy]

Il y a un problème dans ta liste de légumes : tu devrais au moins la limiter à la dernière ligne non vide.

 

[hemardjean]

je sais intégrer une Combobox dans un formulaire ,mais pas quand il n'y en a pas ou faut-il que je la crée

 

[TooFatBoy]

Tu vas dans "Développeur \ Insérer" et tu sélectionnes la ComboBox dans la deuxième partie du menu.
Tu dessines ta ComboBox n'importe où sur ta feuille et de n'importe quelle taille.