Cellules non vides suite export SAP

Sub MisAJour()
 With Worksheets("Sheet1")
 For i = 2 To .Range("A" & Rows.Count).End(xlUp).Row
 ' *** remplissage cellules vides colonnes B, C, L
    If .Cells(i, 2) = "" Then
        .Cells(i, 2) = .Cells(i - 1, 2)
        .Cells(i, 3) = .Cells(i - 1, 3)
        .Cells(i, 12) = .Cells(i - 1, 12)
    End If
 ' *** mise au "format" date colonnes G et H
    If .Cells(i, 7) <> "" Then
        .Cells(i, 7) = CDate(.Cells(i, 7))
        .Cells(i, 8) = CDate(.Cells(i, 8))
    End If
 ' *** mise au "format" numérique colonnes J à R sauf L
    For j = 10 To 18
        If j <> 12 Then
            If .Cells(i, j) <> "" Then
                .Cells(i, j).Replace What:=".", Replacement:=","
                .Cells(i, j) = CDbl(.Cells(i, j))
            End If
        End If
    Next
 Next
 End With
End Sub

'********************************************************************
' Remplace les cellules vides par la valeur de la première
' cellule de taille 0 immédiatement au-dessus ou au-dessous.
' Cette procédure parcours la sélection de HAUT en BAS et inversement
' ATTENTION : Cette procédure utilise la sélection en cours
'********************************************************************
Sub FillLenZeroCellsWithValue()
Dim i As Long
Dim j As Long
Dim nbColonnes As Long
Dim Start As Long
Dim Finish As Long
Dim TopBot As Byte
Dim Direction As Integer
Dim MyArray, Valeur As Variant
Dim MyRange As Range
Dim Msg As String


On Error GoTo GestionErreur


With Application
    .ScreenUpdating = False
    .Calculation = xlCalculationManual
End With


Set MyRange = Selection
With MyRange
    nbColonnes = .Columns.Count
    MyArray = .Value
End With


Msg = "Pour effectuer un remplacement de " & vbCr
Msg = Msg & "HAUT en BAS cliquer sur le bouton OUI" & vbCr
Msg = Msg & "BAS en HAUT cliquer sur le bouton NON"
TopBot = MsgBox(Msg, vbYesNoCancel + vbQuestion, TITLE)
Select Case TopBot
    Case vbCancel
        End
    Case vbYes
        Start = 1: Finish = UBound(MyArray, 1): Direction = 1
    Case Else
        Start = UBound(MyArray, 1): Finish = 1: Direction = -1
End Select
For i = 1 To nbColonnes
    Valeur = ""
    For j = Start To Finish Step Direction
        Select Case Len(MyArray(j, i))
            Case 0
                MyArray(j, i) = Valeur
            Case Else
                Valeur = MyArray(j, i)
        End Select
    Next
Next
MyRange.Value = MyArray
GestionErreur:
With Application
    .ScreenUpdating = True
    .Calculation = xlCalculationAutomatic
End With
End Sub