Calcul prime selon ancienneté

[lfpmarseille]

Bonjour je cherche la formule qui me permet de renseigner le montant de la prime due selon l'ancienneté dans le cadre d'un depart retraite.😕

=SI(H4<=10;K4;SI(H4>=15;L4;SI(H4>=20;M4;SI(H4>=30;N4))))

pour une anciennete >=20 j'ai "faux" dans la cellule!!! je joint le fichier test.
Merci de votre aide et de vos reponses car je bute vraiment!!!
.

 

[Victor21]

Re : Calcul prime selon ancienneté

Bonsoir ifpMarseille.

Excel teste les condtions dans l'ordre où tu les formuls, et s'arrête quand la condition vraie a été rencontrée.
30, c'est plus grand que 20, Excel a trouvé la condition vraie et ne va pas plus loin.

Essaie plutôt :

=SI(H4<=10;K4;SI(H4>=30;N4;SI(H4>=20;M4;SI(H4>=15; L4))))

Edit : D'ailleurs la dernière condition est inutile.

=SI(H4<=10;K4;SI(H4>=30;N4;SI(H4>=20;M4;L4)))

 

[lfpmarseille]

Re : Calcul prime selon ancienneté

C'est parfait .
Un grand merci à vous , je vais pouvoir finaliser mes tableaux!!
Je vous souhaite une excel....ente journée. 🙂
Cordialement.
LFPMARSEILLE

 

[hoerwind]

Re : Calcul prime selon ancienneté

Bonjour, salut Victor,

Il y a un petit problème dans la formule proposée :
SI(H2<=10;K2;SI(H2>=15;L2;SI(...
Que faut-il renvoyer pour une ancienneté entre 10 et 15 ans ?

Je vois plus une formule de ce type :

=SI(H2="";"";DECALER(J2;;1+(H2>=15)+(H2>=20)+(H2>=30)))

Pour le calcul de l'ancienneté, il me semble qu'il faut tenir compte du jour anniversaire (colonne E)
Ici aussi je vois une formule de ce type :

=DATEDIF(E2;P$2;"y")

qui ne renvoie pas les mêmes résultats que celle sous le fichier

Enfin, les colonnes I:N me semblent superflues, la formule suivante renvoie les mêmes résultats :

=SI(H2="";"";F2/P$4*((H2>0)+(H2>=15)+(H2>=20)+(H2>=30))/2)

 

[Victor21]

Re : Calcul prime selon ancienneté

Bonjour, hoerwind.

Merci d'avoir mis le doigt sur mon erreur. Je n'avais pas vu que toutes les plages n'étaient pas couvertes.