Calcul des DJUs méthode Pro

[papi71]

[/B]Bonjour,
J'ai un problème de calculs des Degrés Jours Unifiés avec la méthode des professionnels.
La formule conditionnelle me retourne "Faux" en lieu et place d'une valeur.
La méthode est la suivante:
Pour un calcul de déficits (chauffagiste) de température par rapport au seuil choisi :
source:Calcul des DJU | GRDF Cegibat
- Si S > TX (cas fréquent en hiver) : DJ = S - Moy
- Si S ≤ TN (cas exceptionnel en début ou en fin de saison de chauffe) : DJ = 0
- Si TN < S ≤ TX (cas possible en début ou en fin de saison de chauffe) : DJ = ( S –TN ) * (0.08 + 0.42 * ( S –TN ) / ( TX – TN )
Plus de précisions également sur ma feuille.
Mon calcul est donc:
=SI($C$8>B17;$C$8-$D17; SI($C$8<=$C17;0; SI($C17<$C$8<=$B17;($C$8-$C17)*(0,08+0,42*($C$8-$C17)/($B17-$C17)))))
Pourtant, dans le cas ou la température Maxi est supérieure a la température de référence, ça ne marche pas.
Ma feuille est hébergée sur Ci joint: Document Cjoint ainsi que sur ce site.
Merci a ceux qui pourront maider.
Cordialement.

 

[R@chid]

Re : Calcul des DJUs méthode Pro

Bonjour et Bienvenue sur XLD,
en I17 :

=SI(C$8>B17;0;SI(C$8<=C17;D17-C$8;((B17-C$8)*(0,08+0,42*(B17-C$8)/(B17-C17)))))

@ tirer vers le bas


@ + +

 

[eddy1975]

Re : Calcul des DJUs méthode Pro

Bonjour,

Dans un premier temps regardez la formule et le calcul - Si S ≤ TN : DJ = Moy - S*
C'est écrit $D$17 - $C$8 à l'inverse du calcul donc cela donne un résultat négatif.
Ensuite le premier signe < semble être inversé par rapport à la formule
=SI($C$8<B17;$D$17-$C$8; SI($C$8<=$C17; SI($C17<$C$8<=$B17;($C$8-$C17)*(0,08+0,42*($C$8-$C17)/($B17-$C17)))))

 

[ROGER2327]

Re : Calcul des DJUs méthode Pro

Bonsoir à tous.

Un peu bordélique, tout ça.

Peut-être (comme R@chid) :

=SI(C17<$C$8;SI($C$8<=B17;($C$8-C17)*(0,08+0,42*($C$8-C17)/(B17-C17));$C$8-D17);0)

Ou encore :

=CHOISIR(1+(C17<$C$8)+($C$8<=B17);0;$C$8-D17;($C$8-C17)*(0,08+0,42*($C$8-C17)/(B17-C17)))

Bonne soirée.


ℝOGER2327
#8240

Samedi 28 Pédale 143 (Dédicace du Tripode - Vacuation)
2 Germinal An CCXXIV, 7,4945h - platane
2016-W12-2T17:59:12Z

 

[papi71]

Re : Calcul des DJUs méthode Pro

Bonsoir,
Merci a tous pour vos efforts et plus particulièrement a ROGER2327 pour avoir vu l'erreur initiale, l'avoir corrigé sur la feuille et donc m'apporter toute l'aide dont j'avais besoin.
Cordialement.

 

[babar44]

Bonjour
si quelqu'un au passage connaît un moyen de récupérer les historiques de données de température gratuitement, je suis preneur