XL 2016 Cacher ou (dé)cacher lignes dans plusieurs feuilles automatiquement

Sub Worksheet_Activate()
    UpdateSheet
End Sub

Sub UpdateSheet()
    Dim NbLig%, NoCol%, Deb%, Fin%, Nom$, L%
    On Error GoTo Erreur
    Application.ScreenUpdating = False                                      ' Figer écran
' Détermination de paramètres
    NbLig = Application.CountIf(Sheets("Acceuil").Range("A10:A196"), ">0")  ' Nombre de lignes à récuperer
    Nom = ActiveSheet.Name                                                  ' Nom de la feuille active
    NoCol = Application.Match(Nom, Sheets("Acceuil").[9:9], 0)              ' N° de colonne à récupérer dans Acceuil
    Deb = Application.Match("*quantité*", [D:D], 0) + 1                     ' Début du tableau où ranger
    Fin = Application.Match("*TOTAL HT*", [D:D], 0) - 1                     ' Fin du tableau
' Préparation feuille
    Rows(Deb & ":" & Fin).Hidden = False                                    ' Toutes lignes démasquées
    Range("A" & Deb & ":E" & Fin).ClearContents                             ' Effacement tableau
' Récupération infos
    With Sheets("Acceuil")
        Range("A" & Deb & ":B" & Deb + NbLig) = .Range("A10:B" & 10 + NbLig).Value  ' Copier Coller valeurs Ref et Des.
        Range("D" & Deb & ":D" & Deb + NbLig) = .Range("C10:C" & 10 + NbLig).Value  ' Copier Qté
        ' Transfert données client de la bonne colonne
        Range("C" & Deb & ":C" & Deb + NbLig) = .Range(.Cells(10, NoCol), .Cells(10 + NbLig, NoCol)).Value
' Calcul et masquage lignes
        For L = Deb To Deb + NbLig
            Cells(L, "E") = Cells(L, "C") * Cells(L, "D")                           ' Calcul montant TTC
        Next L
        Rows(Deb + NbLig & ":" & Fin).Hidden = True                                 ' Masque les lignes vides.
    End With
Exit Sub
Erreur:
    MsgBox "Une erreur est intervenue." & Chr(10) & "Vérifiez vos données et leur emplacement."
End Sub

Sub ImpressionFeuille()
    Dim Nom$
    On Error GoTo ErreurImp
    Nom = Application.Caller            ' Qui donc m'a appellé ?
    Sheets(Nom).Activate                ' Selection feuille pour mise à jour
    Worksheets(Nom).PrintPreview        ' Visualisation impression
    Sheets("Acceuil").Activate          ' Retour page d'acceuil
Exit Sub
ErreurImp:
    MsgBox "Une erreur est survenue." & Chr(10) & "Vérifier bien qu'il y a le mêm nom pour :" & Chr(10) & _
            "- Le nom du dessin" & Chr(10) & _
            "- Le nom présent en ligne 9 de Accueil" & Chr(10) & _
            "- Le nom de la feuille correspondante."

End Sub

Sub Masquer()
'se lance par Ctrl+M
Dim a, b, i%, w As Worksheet
a = Array("Accueil", "Hanifatoys1", "ATERNAL", "Arba") 'noms des feuilles à traiter
b = Array(10, 22, 13, 18) '1ères lignes à étudier
For i = 0 To UBound(a)
    Set w = Sheets(a(i))
    With w.Rows(b(i) & ":" & w.Rows.Count)
        .Hidden = False
        On Error Resume Next 'si aucune SpecialCell
        Intersect(w.Range("A" & b(i)).CurrentRegion.Columns(1), .Cells) _
            .SpecialCells(xlCellTypeFormulas, 2).EntireRow.Hidden = True
    End With
Next
End Sub

Sub Tout_Afficher()
'se lance par Ctrl+T
Dim w As Worksheet
For Each w In Sheets(Array("Accueil", "Hanifatoys1", "ATERNAL", "Arba")) 'liste des feuilles à traiter
    w.Rows.Hidden = False
Next
End Sub