XL 2021 bug "lib32" suite à passage à office 2021

#If VBA7 Then
Private Declare PtrSafe Function SetWindowsHookEx Lib "USER32" Alias "SetWindowsHookExA" ( _
ByVal idHook As Long, ByVal lpfn As LongPtr, ByVal hmod As LongPtr, ByVal dwThreadId As Long) As LongPtr
Private Declare PtrSafe Function GetCurrentThreadId Lib "kernel32" () As Long
Private Declare PtrSafe Function CallNextHookEx Lib "USER32" ( _
ByVal hHook As LongPtr, ByVal CodeNo As Long, ByVal wParam As LongPtr, ByVal lParam As LongPtr) As LongPtr
Private Declare PtrSafe Function GetWindow Lib "USER32" ( _
ByVal hwnd As LongPtr, ByVal wCmd As Long) As LongPtr
Private Declare PtrSafe Function SetWindowText Lib "USER32" Alias "SetWindowTextA" ( _
ByVal hwnd As LongPtr, ByVal lpString As String) As Long
Private Declare PtrSafe Function UnhookWindowsHookEx Lib "USER32" (ByVal hHook As LongPtr) As Long
Private msgHook As LongPtr
#Else
Private Declare Function SetWindowsHookEx Lib "USER32" Alias "SetWindowsHookExA" ( _
ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, ByVal dwThreadId As Long) As Long
Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long
Private Declare Function CallNextHookEx Lib "USER32" ( _
ByVal hHook As Long, ByVal CodeNo As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Declare Function GetWindow Lib "USER32" ( _
ByVal hwnd As Long, ByVal wCmd As Long) As Long
Private Declare Function SetWindowText Lib "USER32" Alias "SetWindowTextA" ( _
ByVal hwnd As Long, ByVal lpString As String) As Long
Private Declare Function UnhookWindowsHookEx Lib "USER32" (ByVal hHook As Long) As Long
Private msgHook As Long
#End If

Private TitreBtn(1 To 2) As String

Sub Msgbox3reponses(Optional factice As String)
Dim Rep As Byte
Rep = MsgBoxPerso("Veuillez préciser ce qui doit être récupéré dans le mail", "Question", vbQuestion, "Pièce jointe", "Email", True)

Select Case Rep
Case 0 ' Annuler
MsgBox "annulé !"
Case 1 ' PJ
MsgBox "choix PJ"
Case 2 ' texte Email
MsgBox "choix texte mail"
End Select
End Sub

Function MsgBoxPerso(Prompt As String, Optional Title As String, Optional Icon As VbMsgBoxStyle, _
Optional Caption1 As String = "Oui", Optional Caption2 As String = "Non", Optional Cancel As Boolean = False) As Byte
Dim Rep As VbMsgBoxResult
Dim hInstance As LongPtr
TitreBtn(1) = Caption1
TitreBtn(2) = Caption2
msgHook = SetWindowsHookEx(5, AddressOf CaptionBoutons, hInstance, GetCurrentThreadId())
Rep = MsgBox(Prompt, Icon + IIf(Cancel, vbYesNoCancel, vbYesNo), Title)
MsgBoxPerso = Application.Max(Rep - 5, 0)
Erase TitreBtn
End Function

#If VBA7 Then
Private Function CaptionBoutons(ByVal nCode As Long, ByVal wParam As LongPtr, ByVal lParam As LongPtr) As LongPtr
Dim hWndChild As LongPtr
#Else
Private Function CaptionBoutons(ByVal nCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Dim hWndChild As Long
#End If
If nCode < 0 Then
CaptionBoutons = CallNextHookEx(msgHook, nCode, wParam, lParam)
Exit Function
End If
If nCode = 5 Then
hWndChild = GetWindow(wParam, 5)
Call SetWindowText(hWndChild, TitreBtn(1))
hWndChild = GetWindow(hWndChild, 2)
Call SetWindowText(hWndChild, TitreBtn(2))
UnhookWindowsHookEx msgHook
End If
CaptionBoutons = 0
End Function

Cliquez pour agrandir...