Aux as des formules

[AUBELIX]

Bonjour à tous.
Et par avance, merci pour vos réponses et l'intérêt que vous portez à nos demandes. Site exemplaire pour la qualité de ses intervenants chacun à sa manière. Ma question :

J'ai un classeur dans lequel se trouve une feuille "JOURS_FERIES" avaec les dates des jours fériés. Cette plage est nommée "fériés"
"y" étant l'année et "M" mois encours.
Comment calculer le nombre de jours fériés pour une année et un mois spécifique. Le résultat de ma formule me renvoie 1 jour, alors qu'il y'a 5 jours avec les ponts pour le mois de Mai, ou est l'erreur ?

'=NB.SI(fériés;DATE(y;M;1))

 

[Celeda]

Bonjour,

Si tu vas télécharger Autres Formules III, tu trouveras une page consacrée à ce topic : elle s'appelle Calendrier Fériés,

tu trouveras le nombre de jours fériés par mois
et tu verras aussi les formules associées à ce calendrier

C'est Cathy qui rêve souvent au Soleil qui l'avait proposé,

regarde si cela peut te convenir

Celeda

 

[chris]

Bonjour
Ta formule force la date au 1er mai.
Essayes
=NB.JOURS.OUVRES(DATE(y;M;1);FIN.MOIS(DATE(y;M;1);0);fériés)
Il y a sans doute plus simple avec sommeprod.
Chris

 

[Monique]

Bonjour,

Nb de fériés du mois M, même ceux tombant un dimanche :
=SOMMEPROD((Feries>=DATE(Y;M;1))-(Feries>=DATE(Y;M+1;1)))
=SOMMEPROD((Feries>=DATE(Y;M;1))-(Feries>DATE(Y;M+1😉))

Si tu ne comptes pas les fériés tombant un dimanche :
=SOMMEPROD(((Feries>=DATE(Y;M;1))-(Feries>DATE(Y;M+1😉))*(JOURSEM(Feries)>1))

Si tu ne comptes pas les fériés tombant un samedi ou un dimanche :
=SOMMEPROD(((Feries>=DATE(Y;M;1))-(Feries>DATE(Y;M+1😉))*(JOURSEM(Feries;2)<6))

 

[chris]

Re
Bonjour à Celeda

Je me suis trompée car c'est la formule pour compter les jours ouvrés. Voici les fériés :

=SOMMEPROD((fériés>=DATE(y;M;1))*(fériés<DATE(y;M+1;1))*1)
ou
=SOMME(SI(MOIS(fériés)=M;1;0)) en formule matricielle (valider par ctrl shift entrée)
Chris

 

[chris]

Bonjour
Décidement les filles se croisent !
Bon lundi de pencôte.
Chris

 

[Celeda]

Bonjour


Ah vi !!! vive les filles !!!!!...............................d'XLD !!!!!!



Celeda

 

[AUBELIX]

Les différentes formules fonctionnent à merveille !
Merci à toutes et à tous pour vos réponses.
Le savoir ne vaut que s'il est partagé. Ce forum est une véritable mine d'or
et les intervenants en sont les pépites.
Encore une fois milles mercis.
Bon lundi à tous.

 

[Monique]

Re,

Ton Somme(Si()) est beaucoup plus court, Chris.
En effet, pas besoin de s'occuper du 1er et du 31 du mois.
Idem avec SommeProd.
Tous les fériés :
=SOMMEPROD((MOIS(Feries)=M)*1)
Sauf le dimanche :
=SOMMEPROD((MOIS(Feries)=M)*(JOURSEM(Feries)>1))
Sauf le samedi et le dimanche :
=SOMMEPROD((MOIS(Feries)=M)*(JOURSEM(Feries;2)<6))

 

[chris]

RE
Wouahou
Monique, la reine de la formule a aimé la mienne !
Merci
C'est le souffle de la pentecote !
@ +
Chris