Améliorer une formule

David · 19 Avril 2006

Bonjour le forum,

J'aimerais savoir si il est possible d'améliorer cette formule en la synthétisant ?

=$D$7*(SI(ESTTEXTE(D10);0;1))+$E$7*(SI(ESTTEXTE(E10);0;1))+$F$7*(SI(ESTTEXTE(F10);0;1))+$G$7*(SI(ESTTEXTE(G10);0;1))+$H$7*(SI(ESTTEXTE(H10);0;1))+$I$7*(SI(ESTTEXTE(I10);0;1))+$J$7*(SI(ESTTEXTE(J10);0;1))+$K$7*(SI(ESTTEXTE(K10);0;1))

Merci d'avance pour votre aide.

David

Charly2 · 19 Avril 2006

Bonjour David, bonjour à toutes et à tous

Tu peux essayer ceci :

=SOMMEPROD(ESTTEXTE(D10:K10)*$D$7:$K$7)

A+

michel_m · 19 Avril 2006

salut David, Charly

Charly, c'est quand ce n'est pas texte que l'on additionne (si pour une fois, j'ai bien compris)

=SOMMEPROD(NON(ESTTEXTE(D10:K10))*(D7:K7))

A+
Michel

Charly2 · 19 Avril 2006

Salut Michel

Oups ! :sick:

Mais naturellement, c'est ça que je voulais dire :lol: :lol:

Merci Michel et A+

Monique · 19 Avril 2006

Bonjour,

Ou bien :
=SOMMEPROD(ESTNUM(D10:K10)*D7:K7)
Une cellule vide est considérée comme 'NON(ESTTEXTE())'

David · 20 Avril 2006

Monique écrit:

Bonjour,

Ou bien :
=SOMMEPROD(ESTNUM(D10:K10)*D7:K7)
Une cellule vide est considérée comme 'NON(ESTTEXTE())'

Bonjour Monique, Charly & Michel,

Merci beaucoup pour ces nombreuses réponses qui fonctionnent à merveille.

Une très bonne journée à vous tous.

David

Améliorer une formule

David

Guest

Charly2

Nous a quittés en 2006

michel_m

XLDnaute Accro

Charly2

Nous a quittés en 2006

Monique

Nous a quitté

David

Guest

Discussions similaires