Ajuster l'image à la diapo

[melba]

Bonjour,

voilà je ne connais pas très bien powerpoint. Je souhaiterais savoir comment faire pour que ma copie d'écran ne dépasse pas la taille de la diapo.
Je fais souvent des copies d écran et lorsque je colle , si je veux imprimer ou visualiser je constate que mon image est plus grande que ma diapo. Je dois utiliser les flèches pour l'ajuster. Comme j ai beaucoup de copies d écran à faire cela s avère fastidieux.
Je souhaiterais soit avoir accès aux dimensions de la diapo ou donner une taille constant à mes images ( copies d écran).
Merci pour votre aide.

 

[mromain]

Re : Ajuster l'image à la diapo

Bonjour melba,

La macro suivante redimensionne la forme (ou l'image) sélectionnée. Si aucune image n'est sélectionnée, la macro redimensionne la première forme présente sur la diapositive.

Sub RedimensionnerShape()
Dim image As Shape
    On Error Resume Next
     'essayer de récupérer l'image ou la forme sélectionnée
      Set image = ActiveWindow.Selection.ShapeRange(1)
     'si rien n'était sélectionné, récupérer la première forme de la feuille
      If image Is Nothing Then Set image = ActiveWindow.Selection.SlideRange(1).Shapes(1)
    On Error GoTo 0
    If image Is Nothing Then
        MsgBox "La diapositive ne semble pas contenir d'images."
        Exit Sub
    End If
    'redimensionner l'image / la forme
     With image
        .Left = 0
        .Top = 0
        .Width = .Parent.Design.SlideMaster.Width
        .Height = .Parent.Design.SlideMaster.Height
    End With
End Sub

A+

 

[tototiti2008]

Re : Ajuster l'image à la diapo

Bonjour melba, Bonjour mromain

Pour ceux qui ont des écrans dans des proportions différentes des diapos , une petite modification du code de Mickaël

Sub RedimensionnerShape()
Dim image As Shape, RapportL As Double, RapportH As Double
    On Error Resume Next
     'essayer de récupérer l'image ou la forme sélectionnée
     Set image = ActiveWindow.Selection.ShapeRange(1)
     'si rien n'était sélectionné, récupérer la première forme de la feuille
     If image Is Nothing Then Set image = ActiveWindow.Selection.SlideRange(1).Shapes(1)
    On Error GoTo 0
    If image Is Nothing Then
        MsgBox "La diapositive ne semble pas contenir d'images."
        Exit Sub
    End If
    'redimensionner l'image / la forme
    With image
        .Left = 0
        .Top = 0
        RapportL = .Width / .Parent.Design.SlideMaster.Width
        RapportH = .Height / .Parent.Design.SlideMaster.Height
        If RapportH < RapportL Then
            .Width = .Parent.Design.SlideMaster.Width
        Else
            .Height = .Parent.Design.SlideMaster.Height
        End If
    End With
End Sub

 

[melba]

Re : Ajuster l'image à la diapo

Merci beaucoup pour vos réponses, je testerai dès que possible

@+