XL 2013 Ajouter un lien hypertexte dans la macro qui envoi une invitation outlook

Sbed · 24 Janvier 2023

Bonjour,
Je souhaite joindre un lien hypertexte dans mon invitation outlook envoyée mais je ne trouve pas comment l'écrire. J'ai essayé avec .htmlBody mais ça ne fonctionne pas...

Code:

Sub inviter_texte()
Dim messagerie As Object, invitation As Object, participant As Object, montexte As String, cel As Range
Dim ligne As Long
    Set messagerie = CreateObject("Outlook.Application")
    Set invitation = messagerie.CreateItem(1)
    Workbooks("Outil perso.xlsm").Sheets("Feuil3").Select
    
    corps = corps & "<HTML> <a href="" adresse de mon fichier "" > ici </a> </HTML>"
    
    With invitation
        .MeetingStatus = 1
        .Subject = Range("inv_obj").Value
        .Location = Range("inv_lieu").Value
        .Start = Range("inv_date").Value + Range("inv_heure").Value
        .Duration = Range("inv_durée").Value * 24 * 60
        If Range("inv_rappel").Value > 0 Then
            .ReminderSet = True
            .ReminderMinutesBeforeStart = Range("inv_rappel").Value
        Else
            .ReminderSet = False
        End If

            Set participant = .Recipients.Add(Range("Listeboxsortie").Value)

        .Body = corps
        .Send

    End With

End Sub

Oneida · 25 Janvier 2023

Bonjour,

A voir:

Insérer un lien hypertext dans le body d'un mail piloté par VBA

Bonjour à tous. Voilà, j'ai un peu cherché, et j'ai trouvé des tas de moyens d'insérer des liens dans des cellules ou de lancer un mail via un lien, mais rien pour mon problème... Je l'explique: Sur ma feuille XL, plein de cellules à remplir, des menus déroulants et des cases à cocher...

excel-downloads.com

fanch55 · 25 Janvier 2023

Bonjour,

VB:

Sub inviter_texte()
    
    With CreateObject("Outlook.Application").CreateItem(1)
        .MeetingStatus = 1
        .Subject = Range("inv_obj").Value
        .Location = Range("inv_lieu").Value
        .Start = Range("inv_date").Value + Range("inv_heure").Value
        .Duration = Range("inv_durée").Value * 24 * 60
        If Range("inv_rappel").Value > 0 Then
            .ReminderSet = True
            .ReminderMinutesBeforeStart = Range("inv_rappel").Value
        Else
            .ReminderSet = False
        End If

      ' Set participant = .Recipients.Add(Range("Listeboxsortie").Value)
      
      '  Il faut absolument faire un display au préalable pour accèder au WordEditor
        .display
    
        Cible = "https:/........../....../......"
        Set Wd = .GetInspector.WordEditor
        With Wd
            .Range.Text = "Ceci est ma 1ère ligne avec 2 retours à la ligne" & vbLf & vbLf
            .Range.InsertParagraphAfter
            .Range.Hyperlinks.Add Anchor:=.Paragraphs(.Paragraphs.Count).Range, _
                                  TextToDisplay:="Link", Address:=Cible
            .Range.InsertParagraphAfter
            .Paragraphs(.Paragraphs.Count).Range.Text = "Ceci est ma dernière ligne "
        End With
       ' .Send
    End With

End Sub

Sbed · 25 Janvier 2023

Merci Fanch55 ça marche du tonnerre !

Effectuez une recherche sur Excel Downloads...

XL 2013 Ajouter un lien hypertexte dans la macro qui envoi une invitation outlook

Sbed

XLDnaute Nouveau

Oneida

XLDnaute Impliqué

Insérer un lien hypertext dans le body d'un mail piloté par VBA

fanch55

XLDnaute Barbatruc

Sbed

XLDnaute Nouveau

Discussions similaires

Membres actuellement en ligne

Partager cette page

Tutos vidéos

Statistiques des forums