ajouter donnée dans formule

[edmond]

bonjours à tous le forum.

je me retouve avec deux petit soucis...
la 1ere dans la colonne T/Maj (temps majoré).j'ai voulu rentré une nouvelle
donnée et je me retrouve soit avec des# ou valeur!
dans la ligne 5 et 6 jai 2 services du soirs(S) qui commence avant 11:30(11:21)
la je devrais avoir 9mn de temps majoré.

le 2èm c'est pour la prime panier (P+)
comment rajouté a la formule ,que tout service du soir(S) commencant avant
12:00 et qui ce termine aprés 19:00 alors (P+) voir ligne 4

je tient a vous remercier d'avance de votre aide

 

[Samantha]

Re : ajouter donnée dans formule

Bonjour Edmond,

voici ta formule à mettre en O4 :

=SI(D4="M";SI(I4>14/24;I4-14/24;"");SI(OU(L4="";C4="DFH");"";SI(H4<0,479166666666667;0,479166666666667-H4;SI(L4>"7:40"*1;L4-"7:40";""))))

0,479166666666667 est la valeur de 11:30 en centièmes de journée (pour connaitre les correspondances : juste remettre au format standard la valeur tu peux te faire une table dans un coin de tableau : 1ère colonne format heures tu saisis tes horaires et 2ème colonne tu copies la 1ère colonne, tu sélectionnes toutes les données puis clic droit Format de cellule Onglet Nombre choisir Standard.

Voici la formule à mettre en P4 :
=SI(D4="";"";SI(ET(D4="S";H4<6/24;I4>0,791666666666667);"P+";SI(D4="2X";"P+";SI(D4="500";"";SI(OU(H4<6/24;I4>20/24+1/48);"P+";"")))))

0,789666666666667 est la valeur décimale de 19:00

Dans l'attente de te lire


Sam

 

[Monique]

Re : ajouter donnée dans formule

Bonjour,

Dans la formule, au lieu de 0,479166666666667 on tape 11,5/24 ou "11:30"*1 ou "11:30"/1
Au lieu de 0,789666666666667 on met 19/24 ou "19:00"*1 ou "19:"*1
A la place de 20/24+1/48, on peut mettre 20,5/24 ou "20:30"*1
(je n'ai pas regardé le reste)

 

[edmond]

Re : ajouter donnée dans formule

je te remercie samantha pour ta réponse...
mais.... malheureusement il y a toujour un mais.
ta formule pour le temps majoré de 11:30 fonctionne mais il faudrait que ce soit uniquement pour les services du soir (S)je l'ai appliqué sur ma version complet
les services en 2X, exemple (11:10 a 12:30 et 15:00 a 19:12) la je ne doit pas
avoir de temps majoré.par contre j'ai constaté aussi avec ta formule si je
je commence a 11:21 et termine a 20:00 je devrais avoir 1:08 de t/majoré,car j'ai un service
dépassant 7:40 apparament ca bloque le reste de la formule.

Pour la 2 ém je l'ai appliqué et ca ne marche pas je n'ai pas de P+ qui s'affiche.

je tient encore a te remercie de ton aide

 

[Samantha]

Re : ajouter donnée dans formule

Re Edmond,

Il faut donc coupler la condtion de D4=S avec H4<19:00 la formule devient :
=SI(D4="M";SI(I4>14/24;I4-14/24;"");SI(OU(L4="";C4="DFH");"";SI(ET(D4="S";H4<11,5/24);SOMME(-H4;11,5/24);SI(L4>"7:40"*1;L4-"7:40";""))))

En rouge les corrections qui font que tout devrait bien fonctionner sauf que entre 11:21 et 11:30 il y a 9 mn de tps majoré et non 6 😉

Pour la seconde formule :
=SI(D4="";"";SI(ET(D4="S";H4<=12/24;I4>19/24);"P+";SI(D4="2X";"P+";SI(D4="500";"";SI(OU(H4<6/24;I4>20/24+1/48);"P+";"")))))

Si j'ai bien suivi l'explication de Monique : 12:00 = 12/24 et non 6/24

Voili voilou

A te lire


Sam

 

[edmond]

Re : ajouter donnée dans formule

merci monique de ton aide ,même avec tes modification ca marche pas...
merci quand même.

 

[Samantha]

Re : ajouter donnée dans formule

Qu'est ce qui ne fonctionne pas ?

Qu'attends tu comme résultat ?

Il y a peut être des SI qui sont prioritaire sur d'autres ? - Donnes nous ta hiérarchie de conditons

A te lire


Sam

 

[edmond]

Re : ajouter donnée dans formule

samantha merci de ta reponse ultra rapide
formule P+ fonctionne a merveille...

pour le temps majoré le dépassement des 7:40 ne sont pas comptabilisé
merci de ton remarquable travaille

 

[Samantha]

Re : ajouter donnée dans formule

Re :

Qu'entends tu pas le temps majoré des 7:40

Peux tu me traduire en langage de tous les jours les conditions sur une ligne pour la formule en question avec les informations (dans quelles cellules) le résultat que tu souhaites obtenir en colonne P.

Genre si service du soir (S en colonne D) alors ......

A te lire

Sam
(mais oui on va y arriver 😉)

 

[edmond]

Re : ajouter donnée dans formule

dans mon entreprise les t/majorés sont calculés comme cela
service du matin qui ce termine aprés 14:00
ex. 7:00 a 14:05 la 5mn majoré
service du soir commencant avant 11:30
ex 11:21 a 18:00 la 9mn majoré.
tous les services dont la durée total dépassent 7:40 travaillé dans la colonne L
merci encore

 

[edmond]

Re : ajouter donnée dans formule

voila un exemple de mon roulement de travaille
voir fichier joind

 

[Samantha]

Re : ajouter donnée dans formule

Ah bne voila maintenant qu'on a fini de jouer aux devinettes 😉 lol

=SI(OU(L4="";C4="DFH");"";SI(ET(D4="M";I4>14/24);I4-14/24;SI(ET(D4="S";H4<11,5/24);11,5/24-H4;SI(L4>"7:40"*1;L4-"7:40";""))))

qui signifie :

1. si pas d'heure travaillé OU Type = SAH alors on met rien
2. sinon 4 cas :

• Si service du matin ET heure de fin après 14:00 alors on fait la différence entre 14:00 et l'heure de fin
• Si sevice du matin ET heure de début avant 11:30 alors on fait la différence entre l'heure de début et 11:30
• Si total travaillé supérieur à 7:40 alors on fait la différence entre le total travaillé et 7:40
• aucun des cas précédents alors on met rien

C'était juste une histoire de parenthèses et de groupage de conditons

Cependant question : si on cumule deux conditions :
Service du matin ET début avant 11:30
ET total travaillé supérieur à 7:40

Par exemple Embauche à 11:21 et Débauche à 20:00 on cumule (11:30 - 11:21)+(08:39 - 7:40) ?

Edit : Dans ce cas la formule est :
=SI(OU(L4="";C4="DFH");"";SI(ET(D4="M";I4>14/24;L4>"7:40"*1);(I4-14/24)+(L4-"7:40");SI(ET(D4="S";H4<11,5/24;L4>"7:40"*1);(11,5/24-H4)+(L4-"7:40");SI(ET(D4="M";I4>14/24);I4-14/24;SI(ET(D4="S";H4<11,5/24);11,5/24-H4;SI(L4>"7:40"*1;L4-"7:40";""))))))
et on obtient un Temps majoré de 1:08

A te lire


Sam

 

[edmond]

Re : ajouter donnée dans formule

alors la c'est tout booonnn.
j'en reste bouche bai😱
mille merci sont vraiment peu de chose
alors merci beaucoup😉 😀 😀

 

[edmond]

Re : ajouter donnée dans formule

re bonjour tous le monde,au lieu de faire un nouveau poste,j'ai préféré utiliser celui-ci car c'est pour un complément de la formule des temps majoré, j'espère que vous ne voyez aucune objection que je réutilise celui-ci car je pense que ce seras plus facile pour comprendre le fil.....
Donc la formule des temps majorés fonctionnes très bien ,mais j'aimerais ajouter une nouvel donnée a celle-ci sans la modifier.
Donc: si dans une journée en 2fois(2X) la coupure et inférieure a 2 heures =
temps majoré sauf si c'est supérieure a 2 heures.
pour que ce soit plus claire...
si en en D7=2X et qu'en I7-J7 le temps est inférieur a 2heures en O7 j'ai un
temps majoré car inférieure a 2heures, dans l'exemple fourni de mon fichier
I7=(9h47) et J7=(11h40) la coupure et de 1h53 donc 7mn en O7 car temps
coupure inférieur a 2h.
je vous remercie d'avance de l'aide apporté 😀

 

[edmond]

Re : ajouter donnée dans formule

un petit coup de main pour mon poste ci-dessus
merci😱