Aide please !!!!

[foster_1883]

Pouvez-vous m'aider à adapter la formule ci-dessous avec les paramètres suivants :

le chemin d'enregistrement du pdf doit être : Sheets("X").Range("N21") & "\"
le nom du pdf doit être : Format(Now() - 0, "dd_mmmm_YY")
seul le feuille "x" doit etre enregister en PDF.

le destinataire du couriel doit être : Range("G15").Value

'exporter en format PDF
 ActiveWorkbook.Ex:mad:portAsFixedFormat Type:=xlTypePDF, Filename:=dossierSauvegarde & "\" & NomFichier & ".pdf" _
 , Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
 :=False, OpenAfterPublish:=False
 
 
'envoyer fichier PDF par courriel
 Dim ol As New Outlook.Application
 Dim olmail As MailItem
 Dim CurrFile As String
 Set ol = New Outlook.Application
 Set olmail = ol.CreateItem(olMailItem)
 With olmail
 .To = 'adresse destinataire
 .Subject = ("Nouvelle commande") 'ici le sujet
 .Body = 'ici le corps du mail
 .Attachments.Add dossierSauvegarde & "\" & NomFichier & ".pdf" 'ici la pièce jointe
 .Display '.Display /Send : Display correspond à l'affichage du message / Send demande un envoi direct
 End With

 

[Roland_M]

Re : Aide please !!!!

Bonjour,

voir essai comme ceci !?
je n'ai pas outlook pour essayer !?

Sub NomDeTaRoutine()
NomFeuil$ = "X"
NomFichier$ = Format(Now() - 0, "dd_mmmm_YY") & ".pdf"
DossierSauvegarde$ = Sheets("X").Range("N21")
AdresDestinataire$ = Sheets("X").Range("G15")
CheminFichier$ = DossierSauvegarde$ & "\" & NomFichier$

'Export feuille
Sheets(NomFeuil$).ExportAsFixedFormat Type:=xlTypePDF, Filename:=CheminFichier$, Quality:=xlQualityStandard, _
      IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
 
'envoyer fichier PDF par courriel
Dim ol As New Outlook.Application
Dim olmail As MailItem
Dim CurrFile As String
Set ol = New Outlook.Application
Set olmail = ol.CreateItem(olMailItem)
With olmail
 .To = AdresDestinataire$         'adresse destinataire
 .Subject = "Nouvelle commande"   'ici le sujet
 .Body = "voir ici le message !?" 'ici le corps du mail
 .Attachments.Add CheminFichier$  'ici la pièce jointe
 .Display '.Display pour affichage et Send pour un envoi direct
End With
End Sub