afficher les doublons du grand livre

[Amayelle]

Bonjour le forum,

Je souhaite afficher les données en doublon d'un grand livre en prenant en compte le fait 3
critères, le journal, debit et credit.
J'aimerais que soit colorier toutes les lignes ayant le même code journal, le même montant au debit ou au credit.
Je me permets de vous joindre un fichier
Je remercie d'avance

Sincères salutations

 

[job75]

Bonsoir Amayelle,

Voyez le fichier joint avec les 5 noms définis et les 4 MFC.

Bonne fin de soirée.

 

[Amayelle]

Bonsoir job75, le forum,

Merci pour votre aide et implication
Sincères salutations

 

[job75]

Bonjour Amayelle, le forum,

La solution précédente prend du temps si le tableau est très grand.

Avec 30 000 lignes la modification d'une cellule prend chez moi 3,6 secondes.

Fichier joint.

A+

 

[job75]

Re,

Avec du VBA et 2 Dictionary c'est beaucoup plus rapide.

Le code dans Module1 :

Dim d1 As Object, d2 As Object 'mémorise les variables

Function Test1(x$, y$) As Boolean
If x = "" Or y = "" Then Exit Function
If d1 Is Nothing Then Init
If d1(x & y) > 1 Then Test1 = True
End Function

Function Test2(x$, y$) As Boolean
If x = "" Or y = "" Then Exit Function
If d2 Is Nothing Then Init
If d2(x & y) > 1 Then Test2 = True
End Function

Sub Init()
Dim Journal As Range, J, D, C, i&, x$, y$, z$
Set Journal = Range("B1:B" & Application.Match("zzz", [B:B]) + 1) 'au moins 2 cellules
J = Journal: D = Journal.Offset(, 4): C = Journal.Offset(, 5)
Set d1 = CreateObject("Scripting.Dictionary")
Set d2 = CreateObject("Scripting.Dictionary")
For i = 1 To UBound(J)
  x = J(i, 1): y = D(i, 1): z = C(i, 1)
  If x <> "" And y <> "" Then d1(x & y) = d1(x & y) + 1
  If x <> "" And z <> "" Then d2(x & z) = d2(x & z) + 1
Next
End Sub

Dans le code de la feuille :

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, [B:B,F:G]) Is Nothing Then Init: Application.ScreenUpdating = True
End Sub

Fichiers joints.

Avec 30 000 lignes la modification d'une cellule en colonnes B F G prend 0,15 seconde.

A+