XL 2019 Affichage plein écran

[Ghassen]

Bonjour la tribu

Alors pour afficher mes fichiers en mode plein écran (ou pas) j'utilise ces codes

'A_ Affichage Ecran Normal

Sub Affichage_Normal()
    With Application
        .DisplayFullScreen = False
        .WindowState = xlMaximized
        .DisplayFormulaBar = True
        .DisplayStatusBar = True
        .OnKey "{ESCAPE}"
    End With
    With ActiveWindow
        .DisplayGridlines = False
        .DisplayHeadings = True
        .DisplayWorkbookTabs = True
        .DisplayVerticalScrollBar = True
        .DisplayHorizontalScrollBar = True
    End With
'Et j'ajoute une cellule XX qui prend une valeur False..
End Sub
 
   'B_ Affichage Plein Ecran

Sub Affichage_Plein_Ecran()
    With Application
        .DisplayFullScreen = True
        .WindowState = xlMaximized
        .DisplayFormulaBar = False
        .DisplayStatusBar = False
    End With
    With ActiveWindow
        .DisplayGridlines = False
        .DisplayHeadings = False
        .DisplayWorkbookTabs = False
        .DisplayVerticalScrollBar = False
        .DisplayHorizontalScrollBar = False
    End With
    Application.OnKey "{ESCAPE}", ""
    Application.OnKey "%{ESCAPE}", ""
'Et j'ajoute une cellule XX qui prend une valeur True..
End Sub

Ca marche sans problème sauf si je réduit le fichier excel en question et je le réaffiche, là la barre réapparait,
alors ce que je fais et que j'ajoute généralement un petit bouton avec le code suivant

    '/////////////////////////////////////////////////////////////
    '3- Enlever le ruban quand resize
    '/////////////////////////////////////////////////////////////
Sub Afficheafterresize()

If Cellule(XX).value=True  Then Application.DisplayFullScreen = True '(condition pour s'assurer que le fichier est initialement en mode plein écran)
End Sub

Ma question y'a t il un moyen que le mode plein écran soit figé même après un resize, reduction etc..?
Et merci.

 

[patricktoulon]

Bonjour
le displayfullscreen est fait pour ca justement
afin de t'eviter de perdre les outils
si tu veux vraiment faire disparaitre le ruban
c'est a lui que tu doit t'attaquer

[

Function Affichage_FullScreen()
    ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",0)"    'voila comment on vire le ruban
    With Application
        .WindowState = xlMaximized
        .DisplayFormulaBar = CommandBars("Ribbon").Visible
        .DisplayStatusBar = CommandBars("Ribbon").Visible
        .OnKey "{ESCAPE}", ""
    End With
    With ActiveWindow
        .DisplayGridlines = CommandBars("Ribbon").Visible
        .DisplayHeadings = CommandBars("Ribbon").Visible
        .DisplayWorkbookTabs = CommandBars("Ribbon").Visible
        .DisplayVerticalScrollBar = CommandBars("Ribbon").Visible
        .DisplayHorizontalScrollBar = CommandBars("Ribbon").Visible
    End With
End Function

Function Affichage_Normal()
    ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",1)"    'voila comment on vire le ruban
    With Application
        '****************************************************************************
        'tester les deux pour observer la différence
        ' .WindowState = xlNormal
        '.WindowState = .WindowState    'si tu ne veux pas qu'elle revienne en mode fenetré mais seulement remettre tout les element d'affichage
        '****************************************************************************
        .DisplayFormulaBar = CommandBars("Ribbon").Visible
        .DisplayStatusBar = CommandBars("Ribbon").Visible
    End With
    With ActiveWindow
        .DisplayGridlines = CommandBars("Ribbon").Visible
        .DisplayHeadings = CommandBars("Ribbon").Visible
        .DisplayWorkbookTabs = CommandBars("Ribbon").Visible
        .DisplayVerticalScrollBar = CommandBars("Ribbon").Visible
        .DisplayHorizontalScrollBar = CommandBars("Ribbon").Visible
    End With
    Application.OnKey "{ESCAPE}"
    Application.OnKey "%{ESCAPE}"
End Function

 

[Ghassen]

Salut @patricktoulon
ça répond parfaitement à ma question, merci.