XL 2019 Additionner la hauteur d'un nombre de lignes

[Cédric06400]

Bonjour,

Je cherche à connaitre le résultat dans une cellule de l'addition de plusieurs hauteurs de lignes

Ou pour le dire autrement la hauteur totale d'une sélection de lignes

Merci de votre aide

Cédric

 

[cathodique]

Bonjour,

Si j'ai compris ta demande, à tester

Option Explicit

Sub Hauteur_Plage()
   Dim myRange As Range, cell As Range, H As Double
   On Error Resume Next
   Set myRange = Application.InputBox(prompt:="Selectionner la plage", Type:=8)
   On Error GoTo 0
   If myRange Is Nothing Then
      Exit Sub
   Else
      For Each cell In myRange
         H = H + cell.EntireRow.RowHeight
      Next
   End If

   MsgBox "La hauteur totale des cellules sélectionnées est: " & H
End Sub

 

[job75]

Bonjour Cédric06400, cathodique,

Sub HauteurTotale()
Dim t#, r As Range, h#
t = Timer
ActiveCell.Activate 'si un objet est sélectionné
Selection.EntireRow.Select
For Each r In Selection.Rows
    h = h + r.RowHeight
Next
MsgBox "Plage " & Selection.Address(0, 0) & vbLf & vbLf & "Hauteur totale " & h & vbLf & vbLf & "Durée du calcul " & Format(Timer - t, "0.00 \sec")
End Sub

Pour tester sélectionnez toute la colonne A...

A+

 

[p56]

Bonjour à tous,
On peut aussi aller au plus simple, dans le code le feuille :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    MsgBox Me.Rows(Target.Rows.Count + Target.Row).Top - Me.Rows(Target.Row).Top
End Sub

P.

 

[patricktoulon]

bonjour
@job75 on peut reduire la boucle en bouclant sur les areas

Sub HauteurTotale()
Dim t#, r As Range, h#
t = Timer
ActiveCell.Activate 'si un objet est sélectionné
Selection.EntireRow.Select
For Each area In Selection.Areas
    h = h + area.Height
Next
MsgBox "Plage " & Selection.Address(0, 0) & vbLf & vbLf & "Hauteur totale " & h & vbLf & vbLf & "Durée du calcul " & Format(Timer - t, "0.00 \sec")
End Sub

 

[patricktoulon]

Bonjour à tous,
On peut aussi aller au plus simple, dans le code le feuille :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    MsgBox Me.Rows(Target.Rows.Count + Target.Row).Top - Me.Rows(Target.Row).Top
End Sub

P.

Bonjour @p56 si la sélection est non contiguë c'est mort

 

[patricktoulon]

je corrige
si les cellules sélectionnées sont sur plusieurs colonnes
sans modifier la sélection

Sub HauteurTotale()
Dim t#, r As Range, h#
t = Timer
ActiveCell.Activate 'si un objet est sélectionné
For Each area In Selection.EntireRow.Areas
    h = h + area.Height
Next
MsgBox "Plage " & Selection.Address(0, 0) & vbLf & vbLf & "Hauteur totale " & h & vbLf & vbLf & "Durée du calcul " & Format(Timer - t, "0.00 \sec")
End Sub

 

[patricktoulon]

re

@job75 ta version sur 5000 ligne reparties sur 10000

ma version avec areas

 

[job75]

Areas fonctionne bien si l'on utilise la propriété .Height.

Moi j'ai compris comme cathodique qu'il fallait utiliser .RowHeight.

Cela dit les résultats semblent identiques...

 

[job75]

Cela dit les résultats semblent identiques...

Eh oui ActiveCell.RowHeight donne le même résultat que ActiveCell.Height.

C'est avec les largeurs des colonnes que c'est différent (.Width et .ColumnWidth).

 

[patricktoulon]

re
oui rowheight pareil que height
par contre non les résultats en terme de temps n sont pas identiques
comme je l'ai montré sur 5000 lignes réparties sur 10000 chez toi 0.17 chez moi 0.10
je suppose oui que sur moins de ligne la différence est insignifiante

 

[job75]

Et c'est sûr que pour 1048576 lignes les durées ne sont pas les mêmes !

 

[Cédric06400]

Hello,
Merci à vous tous pour vos contributions.
Je vais étudier tout ça.
belle journée

 

[Cédric06400]

Je viens de me rendre compte que je n'ai pas clôturer cette discussion

Grace à vous tous j'ai réussi à codé exactement ce que j'avais besoin.

Du coup merci à tous

Sub HauteurTotale()
'Calcul la hauteur de la plage définie par le nombre d'arrétés Z321 et renvoie le résultat en AB322
Rows("323:398").EntireRow.AutoFit
Dim t, r As Range, h#
Dim maPlage As Range
t = Range("z321").Value
Set maPlage = Range("A323:A" & t)
For Each area In maPlage.Areas
h = h + area.Height
Next
Range("AB322").Value = h
End Sub